Разница между * и node() в XSLT

в чем разница между этими двумя шаблонами?

<xsl:template match="node()">

<xsl:template match="*">
20
matching templates xslt

3 ответов

<xsl:template match="node()">

- это аббревиатура:

<xsl:template match="child::node()">

это соответствует любому типу узла, который можно выбрать через the child:: ось:

  • элемент

  • текст-узле

  • обработка-инструкция (PI) узел

  • узел комментария.

на другой стороне:

<xsl:template match="*">

это аббревиатура для:

<xsl:template match="child::*">

это соответствует любому элементу.

выражение XPath: someAxis::* соответствует любому узлу первичного типа узла для данной оси.

на child:: axis основной тип узла -элемент.

32

просто чтобы проиллюстрировать одно из различий, а именно, что * не соответствует text:

учитывая xml:

<A>
    Text1
    <B/>
    Text2
</A>

соответствие node()

<xsl:stylesheet
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    version="1.0">
    <xsl:output method="xml" indent="yes" omit-xml-declaration="yes"/>

    <!--Suppress unmatched text-->
    <xsl:template match="text()" />

    <xsl:template match="/">
        <root>
            <xsl:apply-templates />
        </root>
    </xsl:template>

    <xsl:template match="node()">
        <node>
            <xsl:copy />
        </node>
        <xsl:apply-templates />
    </xsl:template>
</xsl:stylesheet>

выдает:

<root>
    <node>
        <A />
    </node>
    <node>
        Text1
    </node>
    <node>
        <B />
    </node>
    <node>
        Text2
    </node>
</root>

в то время как сопоставление на *:

<xsl:template match="*">
    <star>
        <xsl:copy />
    </star>
    <xsl:apply-templates />
</xsl:template>

не соответствует текстовым узлам.

<root>
  <star>
    <A />
  </star>
  <star>
    <B />
  </star>
</root>
13

Смотрите также XSL xsl: шаблон match="/" для других шаблонов соответствия.

2