Разрешить абсолютный путь из относительного пути и/или имени файла

есть ли способ в пакетном скрипте Windows вернуть абсолютный путь из значения, содержащего имя файла и / или относительный путь?

дано:

".."
"..somefile.txt"

мне нужен абсолютный путь к пакетному файлу.

пример:

  • " кое-что.txt " находится в "C:Foo"
  • "тест.bat " находится в "C:FooBar".
  • пользователь открывает командное окно в "C:Foo" и звонит Bartest.bat ..somefile.txt
  • в пакетном файле "C:Foosomefile - ... txt " будет получен из %1

14 ответов


в пакетных файлах, как и в стандартных программах на языке C, аргумент 0 содержит путь к текущему сценарию. Вы можете использовать %~dp0 чтобы получить только часть пути 0-го аргумента (который является текущим скриптом) - этот путь всегда является полным путем.

вы также можете получить полный путь вашего первого аргумента, используя %~f1, но это дает путь в соответствии с текущим рабочим каталогом, который, очевидно, не то, что вы хотите.

лично, Я часто использую %~dp0%~1 идиома в моем пакетном файле, которая интерпретирует первый аргумент относительно пути выполнения пакета. Однако у него есть недостаток: он терпит неудачу, если первый аргумент полностью квалифицирован.

Если вам нужно поддерживать оба относительных и абсолютные пути, вы можете использовать решение Фредерика Менеса: временно измените текущий рабочий каталог.

вот пример, который продемонстрирует каждый из эти приемы:

@echo off
echo %%~dp0 is "%~dp0"
echo %%0 is "%0"
echo %%~dpnx0 is "%~dpnx0"
echo %%~f1 is "%~f1"
echo %%~dp0%%~1 is "%~dp0%~1"

rem Temporarily change the current working directory, to retrieve a full path 
rem   to the first parameter
pushd .
cd %~dp0
echo batch-relative %%~f1 is "%~f1"
popd

если вы сохраните это как c:\temp\example.BAT и запустите его от c:\Users\Public как

c:\Users\Public > \temp\пример.летучая мышь..\окна

...вы увидите следующий вывод:

%~dp0 is "C:\temp\"
%0 is "\temp\example.bat"
%~dpnx0 is "C:\temp\example.bat"
%~f1 is "C:\Users\windows"
%~dp0%~1 is "C:\temp\..\windows"
batch-relative %~f1 is "C:\Windows"

сегодня утром я столкнулся с аналогичной необходимостью: как преобразовать относительный путь в абсолютный путь внутри командного скрипта Windows.

далее сделал свое дело:

@echo off

set REL_PATH=..\..\
set ABS_PATH=

rem // Save current directory and change to target directory
pushd %REL_PATH%

rem // Save value of CD variable (current directory)
set ABS_PATH=%CD%

rem // Restore original directory
popd

echo Relative path: %REL_PATH%
echo Maps to path: %ABS_PATH%

большинство из этих ответов кажутся сумасшедшими из-за сложных и супер багги, вот мой-он работает с любой переменной среды, нет %CD% или PUSHD/POPD или for /f ерунда -- просто старые пакетные функции. -- Каталог и файл даже не должны существовать.

CALL :NORMALIZEPATH "..\..\..\foo\bar.txt"
SET BLAH=%RETVAL%

ECHO "%BLAH%"

:: ========== FUNCTIONS ==========
EXIT /B

:NORMALIZEPATH
  SET RETVAL=%~dpfn1
  EXIT /B

без необходимости иметь другой пакетный файл для передачи аргументов (и использовать операторы аргументов), вы можете использовать FOR /F:

FOR /F %%i IN ("..\relativePath") DO echo absolute path: %%~fi

здесь i на %%~fi - переменная, определенная в /F %%i. например. если вы изменили это на /F %%a тогда последняя часть будет %%~fa.

сделать то же самое прямо в командной строке (а не в пакетном файле) заменить %% С %...


это поможет заполнить пробелы в ответе Адриена Плиссона (который должен быть поддержан, как только он его отредактирует; -):

вы также можете получить полный путь вашего первого аргумента, используя %~f1, но это дает путь в соответствии с текущим путем, который, очевидно, не то, что вы хотите.

к сожалению, я не знаю, как смешать 2 вместе...

можно обрабатывать %0 и %1 дополнительно:

  • %~dpnx0 для полного диска + путь+имя+расширение самого файла batchfile,
    %~f0 тоже хватает;
  • %~dpnx1 для полного диска + путь+имя+расширение его первого аргумента [если это имя файла вообще],
    %~f1 тоже хватает;

%~f1 будет работать независимо от того, как вы указали ваш первый аргумент: с относительными путями или с абсолютными путями (если вы не укажите расширение файла при именовании %1, он не будет добавлен, даже если вы используете %~dpnx1 -- однако.

но как бы вы назвали файл на другом диске в любом случае, если вы не дадите эту полную информацию о пути в командной строке в первую очередь?

, %~p0, %~n0, %~nx0 и %~x0 может пригодиться, если вас интересует путь (без driveletter), имя файла (без расширения), полное имя файла с расширением или только расширение имени файла. Но заметьте, пока %~p1 и %~n1 будет работать, чтобы найти путь или имя первого аргумента, %~nx1 и %~x1 не будет добавлять+показывать расширение, если вы уже не использовали его в командной строке.

вы также можете использовать пакетные функции для этого:

@echo off
setlocal 

goto MAIN
::-----------------------------------------------
:: "%~f2" get abs path of %~2. 
::"%~fs2" get abs path with short names of %~2.
:setAbsPath
  setlocal
  set __absPath=%~f2
  endlocal && set %1=%__absPath%
  goto :eof
::-----------------------------------------------

:MAIN
call :setAbsPath ABS_PATH ..\
echo %ABS_PATH%

endlocal

Я не видел много решений этой проблемы. Некоторые решения используют обход каталогов с помощью CD, а другие-пакетные функции. Мое личное предпочтение было для пакетных функций и, в частности,MakeAbsolute функция как обеспечено DosTips.

функция имеет некоторые реальные преимущества, в первую очередь, что она не изменяет ваш текущий рабочий каталог, а во-вторых, что оцениваемые пути даже не должны существовать. Вы можете найти некоторые полезные советы по использованию функции здесь тоже.

вот пример скрипта и его результаты:

@echo off

set scriptpath=%~dp0
set siblingfile=sibling.bat
set siblingfolder=sibling\
set fnwsfolder=folder name with spaces\
set descendantfolder=sibling\descendant\
set ancestorfolder=..\..\
set cousinfolder=..\uncle\cousin

call:MakeAbsolute siblingfile      "%scriptpath%"
call:MakeAbsolute siblingfolder    "%scriptpath%"
call:MakeAbsolute fnwsfolder       "%scriptpath%"
call:MakeAbsolute descendantfolder "%scriptpath%"
call:MakeAbsolute ancestorfolder   "%scriptpath%"
call:MakeAbsolute cousinfolder     "%scriptpath%"

echo scriptpath:       %scriptpath%
echo siblingfile:      %siblingfile%
echo siblingfolder:    %siblingfolder%
echo fnwsfolder:       %fnwsfolder%
echo descendantfolder: %descendantfolder%
echo ancestorfolder:   %ancestorfolder%
echo cousinfolder:     %cousinfolder%
GOTO:EOF

::----------------------------------------------------------------------------------
:: Function declarations
:: Handy to read http://www.dostips.com/DtTutoFunctions.php for how dos functions
:: work.
::----------------------------------------------------------------------------------
:MakeAbsolute file base -- makes a file name absolute considering a base path
::                      -- file [in,out] - variable with file name to be converted, or file name itself for result in stdout
::                      -- base [in,opt] - base path, leave blank for current directory
:$created 20060101 :$changed 20080219 :$categories Path
:$source http://www.dostips.com
SETLOCAL ENABLEDELAYEDEXPANSION
set "src=%~1"
if defined %1 set "src=!%~1!"
set "bas=%~2"
if not defined bas set "bas=%cd%"
for /f "tokens=*" %%a in ("%bas%.\%src%") do set "src=%%~fa"
( ENDLOCAL & REM RETURN VALUES
    IF defined %1 (SET %~1=%src%) ELSE ECHO.%src%
)
EXIT /b

и вывод:

C:\Users\dayneo\Documents>myscript
scriptpath:       C:\Users\dayneo\Documents\
siblingfile:      C:\Users\dayneo\Documents\sibling.bat
siblingfolder:    C:\Users\dayneo\Documents\sibling\
fnwsfolder:       C:\Users\dayneo\Documents\folder name with spaces\
descendantfolder: C:\Users\dayneo\Documents\sibling\descendant\
ancestorfolder:   C:\Users\
cousinfolder:     C:\Users\dayneo\uncle\cousin

надеюсь, это поможет... Это мне очень помогло. :) П. С. Еще раз спасибо DosTips! Ты крут!


небольшое улучшение превосходное решение BrainSlugs83. Обобщено, чтобы разрешить именование выходной переменной среды в вызове.

@echo off
setlocal EnableDelayedExpansion

rem Example input value.
set RelativePath=doc\build

rem Resolve path.
call :ResolvePath AbsolutePath %RelativePath%

rem Output result.
echo %AbsolutePath%

rem End.
exit /b

rem === Functions ===

rem Resolve path to absolute.
rem Param 1: Name of output variable.
rem Param 2: Path to resolve.
rem Return: Resolved absolute path.
:ResolvePath
    set %1=%~dpfn2
    exit /b

если запускать из C:\project вывод:

C:\project\doc\build

в вашем примере из Bar\test.bat, DIR /B / S ..\некий-файл.txt вернет полный путь.


вы можете просто объединить их.

SET ABS_PATH=%~dp0 
SET REL_PATH=..\SomeFile.txt
SET COMBINED_PATH=%ABS_PATH%%REL_PATH%

это выглядит странно с \..\ в середине вашего пути, но это работает. Не нужно делать ничего сумасшедшего:)


PowerShell довольно распространен в эти дни, поэтому я часто использую его как быстрый способ вызова C#, так как у него есть функции для почти всего:

@echo off
set pathToResolve=%~dp0\..\SomeFile.txt
for /f "delims=" %%a in ('powershell -Command "[System.IO.Path]::GetFullPath( '%projectDirMc%' )"') do @set resolvedPath=%%a

echo Resolved path: %resolvedPath%

это немного медленно, но полученная функциональность трудно превзойти, если не прибегать к фактическому языку сценариев.


решение stijn работает с подпапками под C:\Program Files (86)\,

@echo off
set projectDirMc=test.txt

for /f "delims=" %%a in ('powershell -Command "[System.IO.Path]::GetFullPath( '%projectDirMc%' )"') do @set resolvedPath=%%a

echo full path:    %resolvedPath%

файлы см. все остальные ответы

каталоги

С .. будучи вашим относительным путем и предполагая, что вы находитесь в D:\Projects\EditorProject:

cd .. & cd & cd EditorProject (относительный путь)

возвращает абсолютный путь, например

D:\Projects


SET CD=%~DP0

SET REL_PATH=%CD%..\..\build\

call :ABSOLUTE_PATH    ABS_PATH   %REL_PATH%

ECHO %REL_PATH%

ECHO %ABS_PATH%

pause

exit /b

:ABSOLUTE_PATH

SET %1=%~f2

exit /b