Разрешить только 3 экземпляра приложения с использованием семафоров

Я пытаюсь реализовать простую процедуру, используя семафоры, которые позволят мне запускать только 3 экземпляра приложения. Я мог бы использовать 3 мьютекса, но это не хороший подход, я пробовал это до сих пор

var
  hSem:THandle;
begin
  hSem := CreateSemaphore(nil,3,3,'MySemp3');
  if hSem = 0 then
  begin
    ShowMessage('Application can be run only 3 times at once');
    Halt(1);
  end;

Как я могу сделать это правильно ?

3 ответов


всегда убедитесь, что вы выпускаете семафор, потому что это не делается автоматически, если ваше приложение умирает.

program Project72;

{$APPTYPE CONSOLE}

uses
  Windows,
  SysUtils;

var
  hSem: THandle;

begin
  try
    hSem := CreateSemaphore(nil, 3, 3, 'C15F8F92-2620-4F3C-B8EA-A27285F870DC/myApp');
    Win32Check(hSem <> 0);
    try
      if WaitForSingleObject(hSem, 0) <> WAIT_OBJECT_0 then
        Writeln('Cannot execute, 3 instances already running')
      else begin
        try
          // place your code here
          Writeln('Running, press Enter to stop ...');
          Readln;
        finally ReleaseSemaphore(hSem, 1, nil); end;
      end;
    finally CloseHandle(hSem); end;
  except
    on E: Exception do
      Writeln(E.ClassName, ': ', E.Message);
  end;
end.

можно использовать TJclAppInstances С JCL с.


  1. вы должны попытаться увидеть, если он был создан
  2. вы должны использовать одну из функций ожидания, чтобы увидеть, если вы можете получить количество
  3. в конце вы должны отпустить блокировку и ручку, чтобы она могла работать в следующий раз, когда пользователь закроет и откроет ваше приложение

Ура

var
  hSem: THandle;
begin
  hSem := OpenSemaphore(nil, SEMAPHORE_ALL_ACCESS, True, 'MySemp3');
  if hSem = 0 then
    hSem := CreateSemaphore(nil, 3, 3,'MySemp3');

  if hSem = 0 then
  begin
    ShowMessage('... show the error');
    Halt(1);
    Exit;     
  end;

  if WaitForSingleObject(hSem, 0) <> WAIT_OBJECT_0 then
  begin
    CloseHandle(hSem);
    ShowMessage('Application can be runed only 3 times at once');
    Halt(1);
    Exit; 
  end;

  try   
    your application.run codes..

  finally
    ReleaseSemaphore(hSem, 1, nil);
    CloseHandle(hSem);
  end;