Reify модуль в запись

Предположим, у меня есть произвольный модуль

module Foo where
foo :: Moo -> Goo
bar :: Car -> Far
baz :: Can -> Haz

здесь foo, bar и baz правильно реализовать, и т. д.

Я хотел бы преобразовать этот модуль в автоматически сгенерированный тип данных и соответствующий объект:

import Foo (Moo, Goo, Car, Far, Can, Haz)
import qualified Foo

data FooModule = Foo
  { foo :: Moo -> Goo
  , bar :: Car -> Far
  , baz :: Can -> Haz
  }

_Foo_ = Foo
  { foo = Foo.foo
  , bar = Foo.bar
  , baz = Foo.baz
  }

имена должны быть точно такими же, как оригинальный модуль.

я мог бы сделать это вручную, но это очень утомительно, поэтому я хочу написать код для выполнения этой задачи для меня.

Я не совсем уверен, как подойти к такой задаче. Предоставляет ли шаблон Haskell способ проверки модулей? Должен ли я подключиться к api GHC? Или мне просто повезло с более специальным подходом, таким как соскабливание страниц пикши?

10
ghc-api haskell module template-haskell

1 ответов

(Это для GHC-7.4.2; он, вероятно, не будет компилироваться с HEAD или 7.6 из-за некоторых изменений в Outputable). Я не нашел ничего, чтобы проверить модули в ГО.

{-# LANGUAGE NoMonomorphismRestriction #-}
{-# OPTIONS -Wall #-}
import GHC
import GHC.Paths -- ghc-paths package
import Outputable
import GhcMonad

main :: IO ()
main = runGhc (Just libdir) $ goModule "Data.Map"

goModule :: GhcMonad m => String -> m ()
goModule modStr = do
  df <- getSessionDynFlags
  _ <- setSessionDynFlags df  
  -- ^ Don't know if this is the correct way, but it works for this purpose

  setContext [IIDecl (simpleImportDecl (mkModuleName modStr))]
  infos <- mapM getInfo =<< getNamesInScope 
  let ids = onlyIDs infos
  liftIO . putStrLn . showSDoc . render $ ids 

onlyIDs :: [Maybe (TyThing, Fixity, [Instance])] -> [Id]
onlyIDs infos = [ i | Just (AnId i, _, _) <- infos ] 

render :: [Id] -> SDoc
render ids = mkFields ids $$ text "------------" $$ mkInits ids 

mkFields :: [Id] -> SDoc
mkFields = vcat . map (\i ->
  text "," <+> pprUnqual i <+> text "::" <+> ppr (idType i))

mkInits :: [Id] -> SDoc
mkInits = vcat . map (\i ->
  text "," <+> pprUnqual i <+> text "=" <+> ppr i)


-- * Helpers

withUnqual :: SDoc -> SDoc
withUnqual  = withPprStyle (mkUserStyle neverQualify AllTheWay)

pprUnqual :: Outputable a => a -> SDoc
pprUnqual = withUnqual . ppr
3