Создание приложения Kotlin React с помощью gradle

Я с нетерпением ждал, как создать приложение kotlin-react-с помощью gradle (я знаю с помощью инструмента CLI create-kotlin-react-app, который не использует radle), и я не мог получить никаких источников, чтобы указать мне. Я наткнулся на плагин Kotlin frontend (он работает) и плагин npm и webpack, но я не смог настроить их для запуска/создания Мне проекта kotlin-react. Я не эксперт в настройке webpack, поэтому мне, вероятно, еще сложнее.

начальный Намерения!--3-->

Я намерен создать мультиплатформенный проект (да, Котлинский экспериментальный упакован в IntelliJ)

Альтернативный Подход

когда я потерпел неудачу, я решил пойти с этим подходом.

  1. напишите мой код с помощью Kotlin multiplatform plugin
  2. скомпилируйте его в банку
  3. добавить его в качестве библиотеки в create-react-kotlin-app я бы создать
  4. Run и ждать, пока произойдет магия (это ddnt) Витки вне, некоторые, как предварительно настроенный webpack не компилировался, потому что он не был доступен во время компиляции. но IDE работала хорошо и даже предоставляла код compleion

может кто-нибудь указать мне направление?

6
gradle kotlin kotlin-frontend webpack

1 ответов

создание приложения react с помощью gradle легко при использовании плагина Kotlin frontend. В IntelliJ,выполните следующие действия

новый модуль > gradle > kotlin (Javascript) > [next,next,next...finish]

вам нужно будет настроить gradle ofcourse (на основе того, как вам это нравится).

Я настроил шахты, как показано ниже:

buildscript {
    ext.kotlin_version = '1.2.41'
    ext.kotlinx_html_version = "0.6.4"
    ext.kotlin_frontend_version = "0.0.30"
    ext.react_version = "16.4.0-pre.31-kotlin-$kotlin_version"
    ext.react_dom_version = "16.4.0-pre.31-kotlin-$kotlin_version"
    repositories {
        mavenCentral()
        maven {
            url "https://dl.bintray.com/kotlin/kotlin-eap"
        }
    }
    dependencies {
        classpath "org.jetbrains.kotlin:kotlin-gradle-plugin:$kotlin_version"
        classpath "org.jetbrains.kotlin:kotlin-frontend-plugin:$kotlin_frontend_version"
    }
}
apply plugin: 'org.jetbrains.kotlin.frontend'
apply plugin: 'kotlin2js'
sourceCompatibility = 1.8
repositories {
    mavenLocal()
    mavenCentral()
    jcenter()
    maven { url "http://dl.bintray.com/kotlin/kotlin-dev" }
    maven { url "http://dl.bintray.com/kotlinx/kotlinx" }
    maven { url "http://dl.bintray.com/kotlin/kotlin-js-wrappers" }
}
dependencies {
    compile "org.jetbrains.kotlin:kotlin-stdlib-js:$kotlin_version"
    compile "org.jetbrains.kotlinx:kotlinx-html-js:$kotlinx_html_version"
    compile "org.jetbrains:kotlin-react:$react_version"
    compile "org.jetbrains:kotlin-react-dom:$react_dom_version"
}
kotlinFrontend {
    npm {
        dependency "style-loader" // production dependency
        dependency "react"
        dependency "react-dom"
        dependency "kotlin"
        dependency "@jetbrains/kotlin-extensions"
        dependency "@jetbrains/kotlin-react"
    }
    webpackBundle {
        bundleName = "main"
        sourceMapEnabled = false   // enable/disable source maps
        contentPath = file("${projectDir}/public") // a file that represents a directory to be served by dev server)
        publicPath = "/"  // web prefix
        host = "localhost" // dev server host
        port = 8088   // dev server port
        stats = "errors-only"  // log level
    }
}
task copyDocs(type: Copy) {
    println ":md-react:copyDocs: Copying to public directory"
    from("${projectDir}/build/bundle") {
        include "**/*.js"
        include "*.js"
    }
    into "${projectDir}/public/static"
    println ":md-react:copyDocs: Done copying"
}
task assembleWeb(type: Sync) {
    configurations.compile.each { File file ->
        from(zipTree(file.absolutePath), {
            includeEmptyDirs = false
            include { fileTreeElement ->
                def path = fileTreeElement.path
                (path.endsWith(".js") || path.endsWith(".map")) && (path.startsWith("META-INF/resources/") ||
                        !path.startsWith("META-INF/"))
            }
        })
    }
    from compileKotlin2Js.destinationDir
    into "${projectDir}/build/classes/main"
    dependsOn classes
}
//run.dependsOn copyDocs
assemble.dependsOn assembleWeb
copyDocs.dependsOn bundle
//assemble.finalizedBy(copyDocs)
compileKotlin2Js {
    kotlinOptions.outputFile = "${projectDir}/build/classes/main/web.js"
    kotlinOptions.moduleKind = "umd"
    kotlinOptions.sourceMap = true
}

надеюсь, это поможет вам.

Всего Доброго

6