Список аргументов функции VBA выберите

Я ищу, чтобы сделать что-то вроде следующего:

    Public Function myFunc(vArg1 as string, vArg2 as string, vArg3 as ["A","B","C"])


    End Function

где пользователь получает выпадающий список для vArg3, когда они его вызывают. Это было бы похоже на следующее:

            Public Sub Main()
                Call StrComp("A", "B", vbTextCompare)
            End Sub

где vbTextCompare можно выбрать из предварительно определенного списка или аргументов для функции.

спасибо

6
excel excel-2007 excel-vba vba

2 ответов

Это то, что известно как перечисление. Вот краткий пример:

Public Enum DayOfWeek
    Monday = 1
    Tuesday = 2
    Wednesday = 3
    Thursday = 4
    Friday = 5
    Saturday = 6
    Sunday = 7
End Enum

Public Function GetDrinkSpecial(day As DayOfWeek) As String

    Select Case day
        Case DayOfWeek.Monday
            GetDrinkSpecial = " Tap Domestics"
        Case DayOfWeek.Tuesday
            GetDrinkSpecial = "2 for 1 Rail Mixers"
        Case DayOfWeek.Wednesday
            GetDrinkSpecial = " You-Call-Its"
        Case DayOfWeek.Thursday
            GetDrinkSpecial = " Bush Bottles"
        Case DayOfWeek.Friday
            GetDrinkSpecial = " Greenies"
        Case DayOfWeek.Saturday
            GetDrinkSpecial = "No Specials, Doh!"
        Case DayOfWeek.Sunday
            GetDrinkSpecial = "No Specials, Doh!"
        Case Else
            GetDrinkSpecial = "No Specials, Doh!"
    End Select
End Function

Public Sub TestIt()

    MsgBox GetDrinkSpecial(Monday)
    MsgBox GetDrinkSpecial(Tuesday)
    MsgBox GetDrinkSpecial(Wednesday)
    MsgBox GetDrinkSpecial(Thursday)
    MsgBox GetDrinkSpecial(Friday)
    MsgBox GetDrinkSpecial(Saturday)
    MsgBox GetDrinkSpecial(Sunday)
End Sub

Это получит желаемый эффект "выпадающего списка", который вы ищете при вызове функции в Редакторе VBA. Однако, если вы должны были вызвать "GetDrinkSpecial" из Формулы ячейки excel, у вас не будет доступа к перечислению, и вам нужно будет специально передать ему длинное значение перечисления.

11

не совсем так, как вы просили.

во-первых, вы должны определить "публичное перечисление" для возможных опций в модуле (это может быть тот же модуль, если он не является модулем класса)

Public Enum myFuncEnum
   OPTION_A
   OPTION_B
   OPTION_C
End Enum

тогда в определении функции вы должны иметь:

Public Function myFunc(vArg1 as string, vArg2 as string, vArg3 as myFuncEnum)

End Function

помните, что вы должны сравнить vArg3 с OPTION_A, OPTION_B и OPTION_C вместо "A", "B" и "C". Кстати, OPTION_A, OPTION_B и т. д. могут быть переименованы, чтобы иметь больше смысла, но они должны быть уникальный проект.

2