Узнать из пакетного файла, где установлена Java?

посмотреть получить текущую версию Java из файла BAT чтобы получить текущую установку Java на основе информации, хранящейся в реестре.

это решение зависит от JDK, устанавливаемого в %ProgramFiles%\Java, например C:\Program файлы\Java\jdk1.6.0_18. Вы можете изменить строку " set JDK_Version=1.6 "на версию, которую хотите использовать, например"set JDK_Version=1.5".

предполагая, что последняя версия JDK будет внизу списка (JDK%jdk_Version%*), последняя доступная версия должна быть установлена как JAVA_HOME. Если JDK не удалось найти, JAVA_HOME не будет изменен. Если JDK не может быть найдено и JAVA_HOME не имеет значения, скрипт отобразит сообщение об ошибке.

@echo off
rem set the version of jdk you would like to use (1.4, 1.5, 1.6, etc)
set JDK_Version=1.6

echo.
echo Locating JDK %JDK_Version%

for /d %%i in ("%ProgramFiles%\Java\jdk%jdk_Version%*") do (set Located=%%i)
rem check if JDK was located
if "%Located%"=="" goto else
rem if JDK located display message to user
rem update %JAVA_HOME%
set JAVA_HOME=%Located%
echo     Located JDK %jdk_Version%
echo     JAVA_HOME has been set to:
echo         %JAVA_HOME%
goto endif

:else
rem if JDK was not located
rem if %JAVA_HOME% has been defined then use the existing value
echo     Could not locate JDK %JDK_Version%
if "%JAVA_HOME%"=="" goto NoExistingJavaHome
echo     Existing value of JAVA_HOME will be used:
echo         %JAVA_HOME%
goto endif

:NoExistingJavaHome
rem display message to the user that %JAVA_HOME% is not available
echo     No Existing value of JAVA_HOME is available
goto endif

:endif
rem clear the variables used by this script
set JDK_Version=
set Located=

вы можете использовать значения, хранящиеся в реестре, чтобы автоматически обнаружить, где установлена Java, и настроить переменную JAVA_HOME.

HKLM > Software > JavaSoft > Java Runtime Environment

в этом месте находится ключ, называемый CurrentVersion. Эта версия ссылается на один из каталогов на этом уровне по имени. Открытие каталога предоставляет другой ключ под названием JavaHome. Значение JavaHome-это путь к файловой системе, который можно использовать для определения переменной среды JAVA_HOME.

внутри пакетного файла вы может сделать что-то вроде:

FOR /F "skip=2 tokens=2*" %%A IN ('REG QUERY "HKLM\Software\JavaSoft\Java Runtime Environment" /v CurrentVersion') DO set CurVer=%%B

FOR /F "skip=2 tokens=2*" %%A IN ('REG QUERY "HKLM\Software\JavaSoft\Java Runtime Environment\%CurVer%" /v JavaHome') DO set JAVA_HOME=%%B

Если вы хотите прочитать больше, я написал учебник описание того, что необходимо для создания пакетного файла для автоматического обнаружения JAVA_HOME.

хотя это не идеально, вы можете использовать следующее, чтобы открыть текущую папку JRE:

for /d %%i in ("\Program Files\Java\jre*") do set JAVA_HOME=%%i

если это JDK, который вы хотите, используйте:

for /d %%i in ("\Program Files\Java\jdk*") do set JAVA_HOME=%%i`

для более надежного решения, основанного на проверке реестра Windows, используйте:

set KeyName=HKEY_LOCAL_MACHINE\SOFTWARE\JavaSoft\Java Runtime Environment
set Cmd=reg query "%KeyName%" /s
for /f "tokens=2*" %%i in ('%Cmd% ^| find "JavaHome"') do set JAVA_HOME=%%j

для JDK вам понадобится эта строка:

set KeyName=HKEY_LOCAL_MACHINE\SOFTWARE\JavaSoft\Java Development Kit

Java должен настроить переменную JAVA_HOME, когда она установлена. Используйте это, чтобы найти местоположение Java:

if not "%JAVA_HOME%" == "" goto HasJavaHome

:HasJavaHome
set JAVA_HOME=... // Your new value goes here.

Если JAVA_HOME еще не установлен, и вы хотите его установить, то вам, вероятно, нужно сделать что-то вроде

dir java.exe /B /S

, который даст вам список всех каталогов, содержащих файл Java.исполняемый. Оттуда вы можете передать этот вывод другой команде, которая анализирует результаты и выбирает один из этих каталогов, а затем использует его для установки переменной JAVA_HOME.

вот удобный небольшой пакетный файл, который будет искать все на своем пути для первого появления файла. Волшебный бит-это %%~dp$PATH: i%%i в цикле for. %%~dp развернет следующую переменную только на букву диска и путь. $PATH: i ищет путь для первого появления %%i, который является именем файла, переданным в цикл for.

пример: где.летучая мышь!--5-->

@echo off
setlocal

if "%1"=="" goto USAGE
set filename=%1

for %%i in (%filename%) do @echo %%~dp$PATH:i%%i

goto EOF

:USAGE

echo %0 filename

:EOF
endlocal

это не выполняет поиск по всему жесткому диску. Он только ищет родительское дерево каталогов и поэтому его намного быстрее, чем с помощью "dir java.exe / B / S".

@ECHO off
ECHO ------------------------------------------------------------------
ECHO  Define the location of an existing JDK install by 
ECHO  searching for Javasoft JDK distrobution in parent 
ECHO  directories.
ECHO.
ECHO  Script does not add trailing slash.
ECHO ------------------------------------------------------------------
IF DEFINED JAVA_HOME (
  ECHO JAVA_HOME is already set.
  GOTO :JHSET
)
SET matchobject=Javasoft\bin\java.exe
SET "dir=%~f0"
:LOOP
CALL :FGETDIR "%dir%"
IF EXIST "%dir%\%matchobject%" (
  ECHO Found JAVA_HOME at %dir%\
  GOTO :HOMESET
)
IF "%dir:~-1%" == ":" (
  ECHO Reached root and directory containing "%matchobject%" not found.
  GOTO :EOF
)
GOTO :LOOP
:HOMESET
SET JAVA_HOME=%dir%
GOTO :JHSET
:: function section
:FGETDIR
SET "dir=%~dp1"
SET "dir=%dir:~0,-1%"
EXIT /B 0
:: end function section
:JHSET
:: Does JAVA_HOME have a trailing slash? If so remove it.
IF !JAVA_HOME:~-1!==\ SET JAVA_HOME=!JAVA_HOME:~0,-1!
ECHO JAVA_HOME is %JAVA_HOME%
ECHO Will close in a few seconds...
ping -n 60 127.0.0.1>nul