Выбор непустых ячеек в Excel с помощью VBA

Я только начинаю погружаться в VBA и я ударил немного блокпоста.

У меня есть лист с 50 + столбцами, 900 + строками данных. Мне нужно переформатировать около 10 из этих столбцов и вставить их в новую книгу.

как программно выбрать каждую непустую ячейку в столбце book1, запустить ее через некоторые функции и удалить результаты в book2?

11
excel excel-vba spreadsheet vba

4 ответов

следующий код VBA должен начать работу. Он скопирует все данные в исходной книге в новую книгу, но добавит 1 к каждому значению, и все пустые ячейки будут проигнорированы.

Option Explicit

Public Sub exportDataToNewBook()
    Dim rowIndex As Integer
    Dim colIndex As Integer
    Dim dataRange As Range
    Dim thisBook As Workbook
    Dim newBook As Workbook
    Dim newRow As Integer
    Dim temp

    '// set your data range here
    Set dataRange = Sheet1.Range("A1:B100")

    '// create a new workbook
    Set newBook = Excel.Workbooks.Add

    '// loop through the data in book1, one column at a time
    For colIndex = 1 To dataRange.Columns.Count
        newRow = 0
        For rowIndex = 1 To dataRange.Rows.Count
            With dataRange.Cells(rowIndex, colIndex)

            '// ignore empty cells
            If .value <> "" Then
                newRow = newRow + 1
                temp = doSomethingWith(.value)
                newBook.ActiveSheet.Cells(newRow, colIndex).value = temp
                End If

            End With
        Next rowIndex
    Next colIndex
End Sub



Private Function doSomethingWith(aValue)

    '// This is where you would compute a different value
    '// for use in the new workbook
    '// In this example, I simply add one to it.
    aValue = aValue + 1

    doSomethingWith = aValue
End Function
5

Я знаю, что я очень опаздываю на это, но вот некоторые полезные образцы:

'select the used cells in column 3 of worksheet wks
wks.columns(3).SpecialCells(xlCellTypeConstants).Select

или

'change all formulas in col 3 to values
with sheet1.columns(3).SpecialCells(xlCellTypeFormulas)
    .value = .value
end with

чтобы найти последнюю используемую строку в столбце, никогда не полагайтесь на LastCell, который ненадежен (он не сбрасывается после удаления данных). Вместо этого, я использую что-то вроде 

 lngLast = cells(rows.count,3).end(xlUp).row
14

Если вы ищете последнюю строку столбца, используйте:

Sub SelectFirstColumn()
   SelectEntireColumn (1)
End Sub

Sub SelectSecondColumn()
    SelectEntireColumn (2)
End Sub

Sub SelectEntireColumn(columnNumber)
    Dim LastRow
    Sheets("sheet1").Select
    LastRow = ActiveSheet.Columns(columnNumber).SpecialCells(xlLastCell).Row

    ActiveSheet.Range(Cells(1, columnNumber), Cells(LastRow, columnNumber)).Select
End Sub

другие команды, с которыми вам нужно будет ознакомиться, - это команды копирования и вставки:

Sub CopyOneToTwo()
    SelectEntireColumn (1)
    Selection.Copy

    Sheets("sheet1").Select
    ActiveSheet.Range("B1").PasteSpecial Paste:=xlPasteValues
End Sub

наконец, вы можете ссылаться на таблицы в других книгах, используя следующий синтаксис:

Dim book2
Set book2 = Workbooks.Open("C:\book2.xls")
book2.Worksheets("sheet1")
2

Это может быть полностью вне базы, но вы не можете просто скопировать весь столбец в новую электронную таблицу, а затем отсортировать столбец? Я предполагаю, что вам не нужно поддерживать целостность ордена.

-1