xsl: сортировка XML-файла с использованием нескольких элементов

Я пытаюсь отсортировать кучу записей в XML-файл. Фокус в том, что мне нужно сортировать с помощью разных элементов для разных узлов. Чтобы дать самый простой пример, я хочу сделать это: учитывая xml-файл 

<?xml version="1.0" encoding="utf-8" ?>

<buddies>

<person>
<nick>Jim</nick>
<last>Zulkin</last>
</person>

<person>
<first>Joe</first>
<last>Bumpkin</last>
</person>

<person>
<nick>Pumpkin</nick>
</person>

<person>
<nick>Andy</nick>
</person>

</buddies>

Я хочу преобразовать его в

Andy
Joe Bumpkin
Pumpkin
Jim Zulkin

то есть, человек может быть указан любым подмножеством имя, фамилию и Ник. Ключ сортировки-это фамилия, если она присутствует, в противном случае это псевдоним, если он присутствует, и имя в противном случае.

у меня возникли трудности здесь, так как использование переменных как xsl:ключи сортировки по-видимому, не допускается.

мой текущий лучший снимок - это двухэтапное преобразование: добавьте специальный тег к каждой записи, используя эту таблицу стилей

<?xml version="1.0" encoding="ISO-8859-1"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">

<xsl:output omit-xml-declaration="no" indent="yes"/>

<!-- *** convert each person record into a person2 record w/ the sorting key *** -->
<xsl:template match="/buddies">
    <buddies>
    <xsl:for-each select="person">
     <person2>
        <xsl:copy-of select="*"/>
        <!-- add the sort-by tag -->
        <sort-by>
        <xsl:choose>
            <xsl:when test="last"> <xsl:value-of select="last"/>
            </xsl:when>
            <xsl:otherwise>
                <xsl:choose>
                    <xsl:when test="nick"> <xsl:value-of select="nick"/> </xsl:when>
                    <xsl:otherwise> <xsl:value-of select="first"/> </xsl:otherwise>
                </xsl:choose>
            </xsl:otherwise>
        </xsl:choose>
    </sort-by>
  </person2>
</xsl:for-each>
</buddies>

а затем отсортировать полученный xml 

<?xml version="1.0" encoding="ISO-8859-1"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">

<xsl:template match="/buddies">
    <xsl:apply-templates>
        <xsl:sort select="sort-by"/>
    </xsl:apply-templates>
</xsl:template>

<xsl:template match="person2">
   <xsl:value-of select="first"/>
   <xsl:value-of select="nick"/>
   <xsl:value-of select="last"/><xsl:text>
</xsl:text>
</xsl:template>

в то время как это двухэтапное преобразование работает, мне интересно, есть ли более элегантный способ сделать это всего один раз?

7
xml xpath xslt

2 ответов

можно использовать concat функция XPath:

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output method="text"/>
    <xsl:template match="/buddies">
        <xsl:apply-templates>
            <xsl:sort select="concat(last,nick,first)"/>
        </xsl:apply-templates>
    </xsl:template>
    <xsl:template match="person">
        <xsl:value-of select="concat(normalize-space(concat(first,
                                                            ' ',
                                                            nick,
                                                            ' ',
                                                            last)),
                                     '&#xA;')"/>
    </xsl:template>
</xsl:stylesheet>
5

можно попробовать, если этот шаблон дает ожидаемый результат? Для вашего простого примера он дает правильный ответ, но могут быть угловые случаи, которые не будут работать. Нормализовать-пространство используется здесь, чтобы удалить начальные и конечные пробелы, если один из элементов отсутствует.

<xsl:template match="/buddies">
    <xsl:for-each select="person">
        <xsl:sort select="normalize-space(concat(last, ' ', nick, ' ', first))"/>

        <xsl:if test="first">
            <xsl:value-of select="first" />
            <xsl:text> </xsl:text>
        </xsl:if>

        <xsl:if test="nick">
            <xsl:value-of select="nick" />
            <xsl:text> </xsl:text>
        </xsl:if>

        <xsl:value-of select="last" />
        <xsl:text>&#10;</xsl:text>
    </xsl:for-each>
</xsl:template>
1