Заставить Prolog выбирать уникальные значения переменных

хорошо, я новичок в Prolog, поэтому извините меня, если это что-то тривиальное, но я не могу найти правильный элегантный ответ на это. Я пытаюсь выработать упражнение здесь на learnprolognow.org, упражнение 2.4 (кроссворд).

упражнение предоставляет следующие факты:

   word(astante,  a,s,t,a,n,t,e). 
   word(astoria,  a,s,t,o,r,i,a). 
   word(baratto,  b,a,r,a,t,t,o). 
   word(cobalto,  c,o,b,a,l,t,o). 
   word(pistola,  p,i,s,t,o,l,a). 
   word(statale,  s,t,a,t,a,l,e).

и решение, которое я придумал, чтобы решить кроссворд размещения каждого слова это:

crossword(V1, V2, V3, H1, H2, H3) :-
   word(V1, V1a, V1bH1b, V1c, V1dH2b, V1e, V1fH3b, V1g), 
   word(V2, V2a, V2bH1d, V2c, V2dH2d, V2e, V2fH3d, V2g), 
   word(V3, V3a, V3bH1f, V3c, V3dH2f, V3e, V3fH3f, V3g), 
   word(H1, H1a, V1bH1b, H1c, V2bH1d, H1e, V3bH1f, H1g), 
   word(H2, H2a, V1dH2b, H2c, V2dH2d, H2e, V3dH2f, H2g), 
   word(H3, H3a, V1fH3b, H3c, V2fH3d, H3e, V3fH3f, H3g).

С V1a to V1g etc. быть характерами каждое слово, и V1bH1b to V3fH3f будучи символами, общими между словами в кроссворде.

решение, похоже, работает, однако результат создает повторяющиеся значения, причем первым результатом является:

?- crossword(V1, V2, V3, H1, H2, H3).
V1 = astante,
V2 = baratto,
V3 = statale,
H1 = astante,
H2 = baratto,
H3 = statale .

как я могу заставить Prolog иметь V1 = V2 = V3 = H1 = H2 = H3 ? Если я буду делать их индивидуально, один за другим, мне понадобится 120 перестановок, поэтому должен быть более быстрый способ, и это упражнение для начинающих, поэтому я должен что-то упустить.

я нашел этот же вопрос, Но предоставленные ответы кажутся настолько сложными, я надеюсь, что есть более простой способ. Я использую swi-prolog на Ubuntu, на всякий случай.

спасибо.

7
crossword prolog prolog-dif

3 ответов

использовать alldif/1 определен следующим образом:

alldif([]).
alldif([E|Es]) :-
   maplist(dif(E), Es),
   alldif(Es).

который можно использовать даже для самого общего запроса:

?- alldif(Es).
Es = [] ;
Es = [_G1924] ;
Es = [_G2061, _G2064],
dif(_G2061, _G2064) ;
Es = [_G2163, _G2166, _G2169],
dif(_G2163, _G2169),
dif(_G2163, _G2166),
dif(_G2166, _G2169) ;
Es = [_G2309, _G2312, _G2315, _G2318],
dif(_G2309, _G2318),
dif(_G2309, _G2315),
dif(_G2309, _G2312),
dif(_G2315, _G2318),
dif(_G2312, _G2315),
dif(_G2312, _G2318) ...

смысл цели maplist(dif(E),Es) лучше всего понять, глядя на ответы:

?- maplist(dif(E),Es).
Es = [] ;
Es = [_G1987],
dif(E, _G1987) ;
Es = [_G2040, _G2043],
dif(E, _G2043),
dif(E, _G2040) ;
Es = [_G2093, _G2096, _G2099],
dif(E, _G2099),
dif(E, _G2096),
dif(E, _G2093) ;
Es = [_G2146, _G2149, _G2152, _G2155],
dif(E, _G2155),
dif(E, _G2152),
dif(E, _G2149),
dif(E, _G2146) ...

то есть Es - это список элементов, которые отличаются от E. Цель maplist(dif (E),[A,B,C]) объединяет первый элемент (в данном случае dif(E)) С каждым элементом списка. Таким образом dif(E,A), dif(E,B), dif(E,C).

10

length(List, N): N-длина списка
sort(List, SortedList): SortedList-отсортированная версия списка (дубликаты элементов удаляются)

С другой стороны, это может быть быстрее, есть список из доступных слов и удалить, когда он используется, и не только вам не придется делать проверку в конце, но вы не бессмысленно экземпляров (A1 = foo, A2 = foo остановится немедленно вместо того, чтобы быть отклоненным в конце). Другими словами, обрезка ветвей.

0

либо то, что @false сказал вам в комментариях; или мне нравится использовать выбор домена:

selectM([A|As],S,Z):- select(A,S,S1),selectM(As,S1,Z).
selectM([],Z,Z).

word(astante,  [a,s,t,a,n,t,e]). 
word(astoria,  [a,s,t,o,r,i,a]). 
word(baratto,  [b,a,r,a,t,t,o]). 
word(cobalto,  [c,o,b,a,l,t,o]). 
word(pistola,  [p,i,s,t,o,l,a]). 
word(statale,  [s,t,a,t,a,l,e]).

crossword(Words) :- findall(W, word(_,W), WS),
   Words = [[ _,A,_,B,_,C,_], 
            [ _,D,_,E,_,F,_], 
            [ _,G,_,H,_,I,_],
            [ _,A,_,D,_,G,_],
            [ _,B,_,E,_,H,_],
            [ _,C,_,F,_,I,_]],
   selectM( Words, WS, _).
0