Экспорт форм MS Access и классов / модулей рекурсивно в текстовые файлы?

вы можете использовать доступ.Объект приложения.

кроме того, чтобы избежать нескольких диалоговых окон подтверждения при открытии баз данных, просто измените уровень безопасности в Tools / Macros / Security.

и чтобы открыть несколько баз данных с пользователем / паролем, вы можете присоединиться к рабочей группе (инструменты / безопасность / администратор рабочей группы) и войти в систему с нужным пользователем/паролем (из базы данных с функцией SaveToFile), а затем запустить код. Помните, позже, чтобы присоединиться к рабочая группа по умолчанию (вы можете попытаться присоединиться к несуществующей рабочей группе, и access вернется к умолчанию).

Option Explicit
Option Compare Database


'Save the code for all modules to files in currentDatabaseDir\Code
Public Function SaveToFile()

   On Error GoTo SaveToFile_Err

   Dim Name As String
   Dim WasOpen As Boolean
   Dim Last As Integer
   Dim i As Integer
   Dim TopDir As String, Path As String, FileName As String
   Dim F As Long                          'File for saving code
   Dim LineCount As Long                  'Line count of current module

   Dim oApp As New Access.Application

   ' Open remote database
   oApp.OpenCurrentDatabase ("D:\Access\myDatabase.mdb"), False


   i = InStrRev(oApp.CurrentDb.Name, "\")
   TopDir = VBA.Left(oApp.CurrentDb.Name, i - 1)
   Path = TopDir & "\" & "Code"           'Path where the files will be written

   If (Dir(Path, vbDirectory) = "") Then
      MkDir Path                           'Ensure this exists
   End If

   '--- SAVE THE STANDARD MODULES CODE ---

   Last = oApp.CurrentProject.AllModules.Count - 1

   For i = 0 To Last
      Name = oApp.CurrentProject.AllModules(i).Name
      WasOpen = True                       'Assume already open

         If Not oApp.CurrentProject.AllModules(i).IsLoaded Then
            WasOpen = False                    'Not currently open
            oApp.DoCmd.OpenModule Name              'So open it
         End If

      LineCount = oApp.Modules(Name).CountOfLines
      FileName = Path & "\" & Name & ".vba"

      If (Dir(FileName) <> "") Then
        Kill FileName                      'Delete previous version
      End If

      'Save current version
      F = FreeFile
      Open FileName For Output Access Write As #F
      Print #F, oApp.Modules(Name).Lines(1, LineCount)
      Close #F

      If Not WasOpen Then
         oApp.DoCmd.Close acModule, Name         'It wasn't open, so close it again
      End If
   Next

   '--- SAVE FORMS MODULES CODE ---

   Last = oApp.CurrentProject.AllForms.Count - 1

   For i = 0 To Last
      Name = oApp.CurrentProject.AllForms(i).Name
      WasOpen = True

      If Not oApp.CurrentProject.AllForms(i).IsLoaded Then
         WasOpen = False
         oApp.DoCmd.OpenForm Name, acDesign
      End If

      LineCount = oApp.Forms(Name).Module.CountOfLines
      FileName = Path & "\" & Name & ".vba"

      If (Dir(FileName) <> "") Then
         Kill FileName
      End If

      F = FreeFile
      Open FileName For Output Access Write As #F
      Print #F, oApp.Forms(Name).Module.Lines(1, LineCount)
      Close #F

      If Not WasOpen Then
         oApp.DoCmd.Close acForm, Name
      End If
   Next

   '--- SAVE REPORTS MODULES CODE ---

   Last = oApp.CurrentProject.AllReports.Count - 1

   For i = 0 To Last
      Name = oApp.CurrentProject.AllReports(i).Name
      WasOpen = True

      If Not oApp.CurrentProject.AllReports(i).IsLoaded Then
         WasOpen = False
         oApp.DoCmd.OpenReport Name, acDesign
      End If

      LineCount = oApp.Reports(Name).Module.CountOfLines
      FileName = Path & "\" & Name & ".vba"

      If (Dir(FileName) <> "") Then
         Kill FileName
      End If

      F = FreeFile
      Open FileName For Output Access Write As #F
      Print #F, oApp.Reports(Name).Module.Lines(1, LineCount)
      Close #F

      If Not WasOpen Then
         oApp.DoCmd.Close acReport, Name
      End If
   Next

   MsgBox "Created source files in " & Path

   ' Reset the security level
   Application.AutomationSecurity = msoAutomationSecurityByUI

SaveToFile_Exit:

   If Not oApp.CurrentDb Is Nothing Then oApp.CloseCurrentDatabase
   If Not oApp Is Nothing Then Set oApp = Nothing
   Exit function

SaveToFile_Err:

   MsgBox ("Error " & Err.Number & vbCrLf & Err.Description)
   Resume SaveToFile_Exit

End Function

Я добавил код для модулей отчетов. Когда у меня будет время, я попытаюсь изменить код.

Я считаю это большим вкладом. Спасибо, что поделился.

в отношении

как и для MS Excel, вы также можете использовать цикл над Application.VBE.VBProjects(1).VBComponents и с помощью Export метод экспорта модулей / классов / форм:

Const VB_MODULE = 1
Const VB_CLASS = 2
Const VB_FORM = 100
Const EXT_MODULE = ".bas"
Const EXT_CLASS = ".cls"
Const EXT_FORM = ".frm"
Const CODE_FLD = "Code"

Sub ExportAllCode()

Dim fileName As String
Dim exportPath As String
Dim ext As String
Dim FSO As Object

Set FSO = CreateObject("Scripting.FileSystemObject")
' Set export path and ensure its existence
exportPath = CurrentProject.path & "\" & CODE_FLD
If Not FSO.FolderExists(exportPath) Then
    MkDir exportPath
End If

' The loop over all modules/classes/forms
For Each c In Application.VBE.VBProjects(1).VBComponents
    ' Get the filename extension from type
    ext = vbExtFromType(c.Type)
    If ext <> "" Then
        fileName = c.name & ext
        debugPrint "Exporting " & c.name & " to file " & fileName
        ' THE export
        c.Export exportPath & "\" & fileName
    Else
        debugPrint "Unknown VBComponent type: " & c.Type
    End If
Next c

End Sub

' Helper function that translates VBComponent types into file extensions
' Returns an empty string for unknown types
Function vbExtFromType(ByVal ctype As Integer) As String
    Select Case ctype
        Case VB_MODULE
            vbExtFromType = EXT_MODULE
        Case VB_CLASS
            vbExtFromType = EXT_CLASS
        Case VB_FORM
            vbExtFromType = EXT_FORM
    End Select
End Function

только занимает долю секунды, чтобы выполнить.

Ура

прекрасный ответ клон.

просто небольшое изменение, если вы пытаетесь открыть MDBs, который имеет запуск формы и/или макрос AutoExec и выше, похоже, не всегда работает надежно.

глядя на этот ответ на другом сайте: by pass startup form / macros и прокрутка почти до конца обсуждения-это код, который временно избавляется от настроек формы запуска и извлекает макрос AutoExec на ваш база данных, прежде чем писать над ней с помощью макроса TempAutoExec (который ничего не делает), выполняет некоторую работу (между строками 'Read command bars и app.CloseCurrentDatabase), а затем исправляет все снова.

другой способ-сохранить наиболее используемый код в одном внешнем мастере.MDB-компонента и присоедините его к любому счету *.mdbs корыто модули - >инструменты - >ссылки - >обзор ->...\мастер.mdb

единственная проблема в old 97 Access вы можете отлаживать, редактировать и сохранять непосредственно в пункте назначения.MDB-компонента, но во всех новых, начиная с MA 2000, опция "Сохранить" исчезла и любые предупреждения о закрытом несохраненном коде

IDK, почему никто не предложил это раньше, но вот небольшой фрагмент кода, который я использую для этого. Довольно просто и просто

Public Sub VBAExportModule()
    On Error GoTo Errg
    Dim rs As DAO.Recordset
    Set rs = CurrentDb.OpenRecordset("SELECT MSysObjects.Name FROM MSysObjects WHERE Type=-32761", dbOpenDynaset, dbSeeChanges)

    Do Until rs.EOF
        Application.SaveAsText acModule, rs("Name"), "C:\" & rs("Name") & ".txt"
        rs.MoveNext
    Loop

Cleanup:
    If Not rs Is Nothing Then rs.Close
    Set rs = Nothing
    Exit Sub
Errg:
    GoTo Cleanup
End Sub