Как настроить FastMM для обнаружения утечки памяти в dll

Я не могу понять, как обнаружить утечки памяти в статически или даже динамически связанной dll. Я просто хочу обнаружить утечки в dll, и я не хочу делиться менеджером памяти между dll и приложением. Кроме того, dll является связан с пакетами времени выполнения

мой пример dll выглядит так:

library dll;
uses
  fastmm4,
  System.SysUtils,
  System.Classes;
{$R *.res}
procedure MyInit; stdcall;
Begin
  TObject.Create;
End;
exports MyInit;
begin
end.

применение dpr:

program app;

uses
  //fastmm4,
  Vcl.Forms,
  main in 'main.pas' {Form1};

{$R *.res}

begin
  Application.Initialize;
  Application.MainFormOnTaskbar := True;
  Application.CreateForm(TForm1, Form1);
  Application.Run;
end.

Примечание: Если я раскомментирую fastmm4, чем я могу обнаружить memleak, вызванный приложением (TStringList.Create), но не утечка в dll.

и в главном блоке Приложения:

unit main;

interface

uses
  Winapi.Windows, Winapi.Messages, System.SysUtils, System.Variants, System.Classes, Vcl.Graphics,
  Vcl.Controls, Vcl.Forms, Vcl.Dialogs, Vcl.StdCtrls;

type
  TForm1 = class(TForm)
    procedure FormCreate(Sender: TObject);
  private
    LDLLHandle: HModule;
    LShowProc: TProcedure;
  end;

var
  Form1: TForm1;

{$ifdef static}
procedure MyInit; stdcall; external 'dll.dll';
{$endif}

implementation

{$R *.dfm}

procedure TForm1.FormCreate(Sender: TObject);
begin
  TStringList.Create;
  {$ifdef static}
  MyInit;
  {$else}
  LDLLHandle := LoadLibrary('dll.dll');
  if LDLLHandle <> 0 then
  begin
    try
      LShowProc := GetProcAddress(LDLLHandle, 'MyInit');
      if Assigned(LShowProc) then
        LShowProc;
    finally
      FreeLibrary(LDLLHandle);
    end;
  end;
  {$endif}
end;

end.

Я ожидаю от FastMM генерировать отчет при вызове FreeLibrary или при выходе из программы, если dll статически загружена, но ничего не происходит.

на FastMM4Options.inc кроме того, я просто поставил FullDebugMode и ClearLogFileOnStartup и FastMM_FullDebugMode.dll файлы в выходной справочник.

Я создал репозиторий на github. Что я упускаю?

7
delphi delphi-xe3 dll fastmm

2 ответов

причина, по которой ваша DLL не сообщает об утечках, проистекает из этого кода при выключении FastMM:

  CheckBlocksOnShutdown(
  {$ifdef EnableMemoryLeakReporting}
        True
    {$ifdef RequireIDEPresenceForLeakReporting}
        and DelphiIsRunning
    {$endif}
    {$ifdef RequireDebuggerPresenceForLeakReporting}
        and ((DebugHook <> 0)
        {$ifdef PatchBCBTerminate}
        or (Assigned(pCppDebugHook) and (pCppDebugHook^ <> 0))
        {$endif PatchBCBTerminate}
        )
    {$endif}
    {$ifdef ManualLeakReportingControl}
        and ReportMemoryLeaksOnShutdown
    {$endif}
  {$else}
        False
  {$endif}
  );

в параметрах, RequireDebuggerPresenceForLeakReporting определяется. Более того, в DLL, DebugHook равна 0, предположительно, потому, что вы отлаживаете приложение, а не DLL. Это означает, что вы называете CheckBlocksOnShutdown передает False. И это False отключить отчеты об утечках.

вы можете решить эту проблему, не определив RequireDebuggerPresenceForLeakReporting.

5

Я просто тестирую его с версией Fast Memory Manager 4.97 на Delphi2010-win7

  1. FastMM4 является первой единицей в предложении "uses".dpr (проект и dll)
  2. опция "ShareMM" включена
    3. 'AttemptToUseSharedMM' включена 'EnableMemoryLeakReporting' включена

Добавить FastMM_FullDebugMode.dll в папке exe

существует также динамически загружаемая тестовая демонстрация ДЛЛ' Это демо без ShareMem. Я должен установить опцию "ShareMM" и "AttemptToUseSharedMM" и добавить FastMM_FullDebugMode.dll, чтобы иметь отчет об утечке FastMM.

-1