Как перечислить всю папку с размером через пакетный файл

Я хочу простое решение для списка папок и их размера в формате txt или csv.

Я использую этот код для списка папок

dir C:Temp*.* /b /a:d > C:folderList.txt

выходной ток

<<folderList.txt>>
folder1
folder2
folder3

нужный выход

<<folderList.txt>>
folder1 # 100 MB
folder2 # 30 MB
folder3 # 110 MB

просто он будет генерировать размер каждой папки.. Как я могу продолжать?? любая помощь

10
batch-file dir folder size windows

6 ответов

для каждой папки в списке, используйте для получения размера файлов в папке

@echo off
    setlocal disabledelayedexpansion

    set "folder=%~1"
    if not defined folder set "folder=%cd%"

    for /d %%a in ("%folder%\*") do (
        set "size=0"
        for /f "tokens=3,5" %%b in ('dir /-c /a /w /s "%%~fa\*" 2^>nul ^| findstr /b /c:"  "') do if "%%~c"=="" set "size=%%~b"
        setlocal enabledelayedexpansion
        echo(%%~nxa # !size!
        endlocal
    )

    endlocal

он выполняет итерацию по указанной папке (передается как параметр в пакетный файл или текущий каталог, если нет параметра).

для каждой папки внутри него (for /d) рекурсивный dir команда выполняется внутри внутренней for команда, а из ее вывода-строка сводки в конце (извлекается findstr) анализируется (тег tokens in

17

используя отличный код MC ND, я добавил преобразование в КБ, Мб, Гб и т. д. На всякий случай, если вы предпочитаете иметь его в этих форматах. 

@echo off
setlocal disabledelayedexpansion

set "folder=%~1"
  if not defined folder set "folder=%cd%"

    for /d %%a in ("%folder%\*") do (
        set "size=0"
        for /f "tokens=3,5" %%b in ('dir /-c /a /w /s "%%~fa\*" 2^>nul ^| findstr /b /c:"  "') do if "%%~c"=="" set "size=%%~b"
        setlocal enabledelayedexpansion
        call :GetUnit !size! unit
        call :ConvertBytes !size! !unit! newsize
        echo(%%~nxa - !newsize! !unit!
        endlocal
    )

endlocal
exit /b

:ConvertBytes bytes unit ret
setlocal
if "%~2" EQU "KB" set val=/1024
if "%~2" EQU "MB" set val=/1024/1024
if "%~2" EQU "GB" set val=/1024/1024/1024
if "%~2" EQU "TB" set val=/1024/1024/1024/1024
> %temp%\tmp.vbs echo wsh.echo FormatNumber(eval(%~1%val%),1)
for /f "delims=" %%a in ( 
  'cscript //nologo %temp%\tmp.vbs' 
) do endlocal & set %~3=%%a
del %temp%\tmp.vbs
exit /b


:GetUnit bytes return
set byt=00000000000%1X
set TB=000000000001099511627776X
if %1 LEQ 1024 set "unit=Bytes"
if %1 GTR 1024   set "unit=KB"
if %1 GTR 1048576  set "unit=MB"
if %1 GTR 1073741824  set "unit=GB"
if %byt:~-14% GTR %TB:~-14% set "unit=TB"
endlocal & set %~2=%unit%
exit /b
11

мой JREN.Утилита летучей мыши можно использовать для получения списка папок с размерами. Это гибридный скрипт JScript / batch, который запускается изначально на любой машине Windows с XP.

JREN не удобно конвертировать в MB (или любой другой блок) - он просто перечисляет размер в байтах. Но это, конечно, удобно (и сравнительно быстро), чтобы получить список:

jren "$" "' # '+size()" /d /j /list /p "d:\temp" >"C:\folderList.txt"

вы можете рассмотреть вопрос о том, чтобы поместить размер папки во-первых, пространство заполнено до фиксированной ширины, которая превышает самая большая папка, за которой следует имя папки. Я нахожу этот формат намного проще для чтения, и его по-прежнему легко разобрать:

jren "^" "size('               ')+'  '" /d /j /list /p "d:\temp" >"C:\folderList.txt"

вывод будет выглядеть примерно так

           1852  SomeFolderName
        1616869  Another folder name
         137764  yetAnother

поскольку JREN является пакетным файлом, вы должны использовать вызов JREN, если вы помещаете команду в другой пакетный скрипт.

1

Если вы используете windows 7 или new, используйте powershell и введите команду

ls-r > > журнал.txt

Он будет перечислять все файлы в текущем каталоге вместе с размером файла в байтах в файл журнала.

1

попробовать sed для Windows:

dir /-c /a /w /s|sed -nr "/:$/q;/:/h;/^\s+[0-9]/{s/.*[^0-9]([0-9]+.*)//;H;g;s/\n/ /p}"
0

Я взял код @Matt Williamsons и заставил его экспортировать каждую строку в a .csv-файл в каталоге run, folderSizes.csv. Он предоставляет полный размер байта в виде столбца, чтобы вы могли легко сортировать в excel (или что-то еще).

@echo off
echo Getting folder sizes for you...storing to folderSizes.csv
setlocal disabledelayedexpansion
if EXIST folderSizes.csv del folderSizes.csv
echo Folder,Bytes Size,Short Size > folderSizes.csv

set "folder=%~1"
  if not defined folder set "folder=%cd%"

    for /d %%a in ("%folder%\*") do (
        set "size=0"
        for /f "tokens=3,5" %%b in ('dir /-c /a /w /s "%%~fa\*" 2^>nul ^| findstr /b /c:"  "') do if "%%~c"=="" set "size=%%~b"
        setlocal enabledelayedexpansion
        call :GetUnit !size! unit
        call :ConvertBytes !size! !unit! newsize
        echo(%%~nxa,!size!,!newsize!!unit! >> folderSizes.csv
        endlocal 
    )

endlocal
exit /b

:ConvertBytes bytes unit ret
setlocal
if "%~2" EQU "KB" set val=/1024
if "%~2" EQU "MB" set val=/1024/1024
if "%~2" EQU "GB" set val=/1024/1024/1024
if "%~2" EQU "TB" set val=/1024/1024/1024/1024
> %temp%\tmp.vbs echo wsh.echo FormatNumber(eval(%~1%val%),1)
for /f "delims=" %%a in ( 
  'cscript //nologo %temp%\tmp.vbs' 
) do endlocal & set %~3=%%a
del %temp%\tmp.vbs
exit /b


:GetUnit bytes return
set byt=00000000000%1X
set TB=000000000001099511627776X
if %1 LEQ 1024 set "unit=Bytes"
if %1 GTR 1024   set "unit=KB"
if %1 GTR 1048576  set "unit=MB"
if %1 GTR 1073741824  set "unit=GB"
if %byt:~-14% GTR %TB:~-14% set "unit=TB"
endlocal & set %~2=%unit%
exit /b
0