Как перенести данные из столбцов в строки (с awk)?

у меня есть файл такой:

n A B C D 
1 01 02 01 01
2 02 02 01 01

и я хочу перенести столбцы по строкам, поэтому вывод должен быть таким:

n 1 2
A 01 02
B 02 02
C 01 01 
D 01 01

Я написал эту команду:

awk '{ for (i=1;i<=NF;i++ ) printf $i " " }' file.txt > out-file.txt

проблема в том, что эта команда поставила все на одну строку! так что вывод такой:

n 1 2 A 01 02 B 02 02 C 01 01 D 01 01
10
awk linux rows

5 ответов

Это может сработать:

awk '{
       for (f = 1; f <= NF; f++) { a[NR, f] = $f } 
     }
     NF > nf { nf = NF }
     END {
       for (f = 1; f <= nf; f++) {
           for (r = 1; r <= NR; r++) {
               printf a[r, f] (r==NR ? RS : FS)
           }
       }
    }' YOURINPUT

видеть в действии @ Ideone.

7

Сохраните этот скрипт как транспонировать.awk и chmod u+x transpose.awk. Это модификация Тима Шервуда transpose.

#!/usr/bin/gawk -f

BEGIN {
    max_x =0;
    max_y =0;
}

{
    max_y++;
    for( i=1; i<=NF; i++ )
    {
        if (i>max_x) max_x=i;
        A[i,max_y] = $i;
    }
}

END {
    for ( x=1; x<=max_x; x++ )
    {
        for ( y=1; y<=max_y; y++ )
        {
            if ( (x,y) in A ) printf "%s",A[x,y];
            if ( y!=max_y ) printf " ";
        }
        printf "\n";
    }
}

пример:

$ ./transpose.awk example
n 1 2
A 01 02
B 02 02
C 01 01
D 01 01
3

Было бы проще использовать rs:

$ cat /tmp/a
n A B C D
1 01 02 01 01
2 02 02 01 01
$ rs -c' ' -C' ' -T</tmp/a
n 1 2
A 01 02
B 02 02
C 01 01
D 01 01

-c изменяет разделитель входного столбца,-C изменяет разделитель выходного столбца и -T перемещение строк и столбцов.

3

Ну, без awk мы можем сделать это с cat:

for x in `cat filename`
do
echo $x
done

С помощью этого скрипта результат появится в cols.

1

вот другое решение, которое включает только один цикл for В конце:

{ for (i=1; i<=NF; i++) col[i] = col[i] " " $i }
END { 
    for (i=1; i<=NF; i++) { 
        sub(/^ /, "", col[i]); 
        print col[i] 
    } 
}

Обсуждение

  • это решение использует одномерный массив col, в котором хранится значение для всего столбца. col[1] первый столбец.
  • для каждой строки мы добавляем столбец в col[i]. Потому что мы слепо добавляем,col[i] значение будет содержать пробел.
  • в конце, подводная лодка() функция удаляет ведущее пустое пространство перед печатью столбца (теперь строка)
0