Как преобразовать строку ISO 8601 в Delphi TDate?

Я могу легко конвертировать Delphi TDate в формат ISO 8601, используя это:

DateTimeToString(result, 'yyyy-mm-dd', myDate);

в чем идиоматические способ сделать обратное преобразование? StringToDateTime() Кажется, не существует.

очевидно, я могу сделать это "трудным" способом, вручную разбирая строку и кодируя результат, но это кажется плохим выбором.

17
delphi iso8601

7 ответов

зачем заново изобретать колесо?

XML использует ISO 8601 для хранения даты и времени.

Delphi имеет встроенную поддержку для этого, так как Delphi 6 в XSBuiltIns единица.

этот ответ объясняет, как для DateTime это для даты только с помощью TXSDate класс:

with TXSDate.Create() do
  try
    AsDate := Date; // convert from TDateTime
    DateString := NativeToXS; // convert to WideString
  finally
    Free;
  end;

with TXSDate.Create() do
  try
    XSToNative(DateString); // convert from WideString
    Date := AsDate; // convert to TDateTime
  finally
    Free;
  end;
16

начиная с XE8, используйте ISO8601ToDate (и DateToISO8601) от dateutils.pas.

http://docwiki.embarcadero.com/Libraries/XE8/en/System.DateUtils.ISO8601ToDate

12

вы можете найти процедуры преобразования Iso-8601 в нашем SynCommons unit.

Он был глубоко оптимизирован для скорости, поэтому он намного быстрее, чем функции DateTimeToString() и такие, но, конечно, код сложнее следовать. ;)

procedure Iso8601ToDateTimePUTF8CharVar(P: PUTF8Char; L: integer; var result: TDateTime); 
var i: integer;
    B: cardinal;
    Y,M,D, H,MI,SS: cardinal;
// we expect 'YYYYMMDDThhmmss' format but we handle also 'YYYY-MM-DD hh:mm:ss'
begin
  result := 0;
  if P=nil then
    exit;
  if L=0 then
    L := StrLen(P);
  if L<4 then
    exit; // we need 'YYYY' at least
  if P[0]='T' then
    dec(P,8) else begin
    B := ConvertHexToBin[ord(P[0])]; // first digit
    if B>9 then exit else Y := B; // fast check '0'..'9'
    for i := 1 to 3 do begin
      B := ConvertHexToBin[ord(P[i])]; // 3 other digits
      if B>9 then exit else Y := Y*10+B;
    end;
    if P[4] in ['-','/'] then begin inc(P); dec(L); end; // allow YYYY-MM-DD
    D := 1;
    if L>=6 then begin // YYYYMM
      M := ord(P[4])*10+ord(P[5])-(48+480);
      if (M=0) or (M>12) then exit;
      if P[6] in ['-','/'] then begin inc(P); dec(L); end; // allow YYYY-MM-DD
      if L>=8 then begin // YYYYMMDD
        D := ord(P[6])*10+ord(P[7])-(48+480);
        if (D=0) or (D>MonthDays[true][M]) then exit; // worse is leap year=true
      end;
    end else
      M := 1;
    if M>2 then // inlined EncodeDate(Y,M,D)
      dec(M,3) else
    if M>0 then begin
      inc(M,9);
      dec(Y);
    end;
    with Div100(Y) do
      result := (146097*YDiv100) shr 2 + (1461*YMod100) shr 2 +
            (153*M+2) div 5+D-693900;
    if (L<15) or not(P[8] in [' ','T']) then
      exit;
  end;
  H := ord(P[9])*10+ord(P[10])-(48+480);
  if P[11]=':' then inc(P); // allow hh:mm:ss
  MI := ord(P[11])*10+ord(P[12])-(48+480);
  if P[13]=':' then inc(P); // allow hh:mm:ss
  SS := ord(P[13])*10+ord(P[14])-(48+480);
  if (H<24) and (MI<60) and (SS<60) then // inlined EncodeTime()
    result := result + (H * (MinsPerHour * SecsPerMin * MSecsPerSec) +
             MI * (SecsPerMin * MSecsPerSec) + SS * MSecsPerSec) / MSecsPerDay;
end;

Это может обрабатывать очень быстрое преобразование из буфера с кодировкой UTF-8 в TDateTime. Для всех зависимостей констант проверьте исходный код единицы измерения.

7

Я думаю, это должно сработать... в документации говорится, что перегруженная версия этих методов предназначена для использования в потоках, но может быть удобна для указания параметров формата, которые вы хотите использовать в то время.

Function ISO8601ToDateTime(Value: String):TDateTime;
var
    FormatSettings: TFormatSettings;
begin
    GetLocaleFormatSettings(GetThreadLocale, FormatSettings);
    FormatSettings.DateSeparator := '-';
    FormatSettings.ShortDateFormat := 'yyyy-MM-dd';
    Result := StrToDate(Value, FormatSettings);
end;

вы можете, конечно, написать варианты этого с StrToDateDef и TryStrToDate с эквивалентной функциональностью

7

для большей гибкости вы можете рассмотреть Марко ван де Воорт ' s скандатные рутинную который обрабатывает вашу строку в любом формате:

var
  D: TDateTime;
begin
  D := ScanDate('yyyy-mm-dd', '2011-07-11');

посмотреть окончательный вариант (7kB .zip), как добавлено в FPC.

6
USES Soap.XSBuiltIns;
...
Function XMLDateTimeToLocalDateTime(const Value: String): TDateTime;
begin
  with TXSDateTime.Create do
  try
    XSToNative(Value);
    result := AsDateTime;
  finally
    Free;
  end;
end;

Делфи XE3 установлены

1

начиная с XE6 вы можете использовать функцию System.DateUtils.ISO8601ToDate:

uses
  System.DateUtils;
var
  vDat: TDateTime;
begin
  vDat := ISO8601ToDate('2018-03-26T11:01:35.867Z');
end.
0