Как протестировать хранимую процедуру Oracle с типом возврата RefCursor?

Я ищу хорошее объяснение того, как протестировать хранимую процедуру Oracle в SQL Developer или Embardero Rapid XE2. Спасибо.

32
oracle plsqldeveloper rapidsql ref-cursor stored-procedures

6 ответов

что-то вроде

create or replace procedure my_proc( p_rc OUT SYS_REFCURSOR )
as
begin
  open p_rc
   for select 1 col1
         from dual;
end;
/

variable rc refcursor;
exec my_proc( :rc );
print rc;

будет работать в SQL * Plus или SQL Developer. У меня нет опыта работы с Embarcardero Rapid XE2, поэтому я понятия не имею, поддерживает ли он такие команды SQL*Plus.

57

что-то вроде этого позволяет протестировать процедуру практически на любом клиенте:

DECLARE 
  v_cur SYS_REFCURSOR;
  v_a   VARCHAR2(10);
  v_b   VARCHAR2(10);
BEGIN
  your_proc(v_cur);

  LOOP
    FETCH v_cur INTO v_a, v_b;
    EXIT WHEN v_cur%NOTFOUND;
    dbms_output.put_line(v_a || ' ' || v_b);
  END LOOP;
  CLOSE v_cur;
END;

в основном, ваш тестовый жгут должен поддерживать определение SYS_REFCURSOR переменная и возможность вызова процедуры при передаче переменной, которую вы определили, а затем цикл через результирующий набор курсора. PL/SQL делает все это, и анонимные блоки просты в настройке и обслуживании, довольно адаптируемы и вполне читаемы для всех, кто работает с PL / SQL.

другое, хотя и аналогичным образом можно было бы построить именованную процедуру, которая делает то же самое, и предполагая, что у клиента есть отладчик (например, SQL Developer, PL/SQL Developer, TOAD и т. д. затем вы можете пройти через казнь.

21

в SQL Developer вы можете щелкнуть правой кнопкой мыши на теле пакета и выбрать выполнить. Окно "Выполнить PL/SQL" позволит вам редактировать блок PL/SQL. При нажатии кнопки " ОК "появится окно" выходные переменные - журнал "с вкладкой " выходные переменные". Вы можете выбрать выходные переменные слева, а результат отображается справа. Очень удобно и быстро.

Я использовал Rapid с T-SQL, и я думаю, что было что-то похожее на это.

написание собственных сценарий delcare-begin-end, в котором вы перебираете курсор, как в Примере DCookie, всегда является хорошим упражнением, которое нужно делать время от времени. Он будет работать с чем угодно и вы будете знать, что ваш код работает.

7

в Toad 10.1.1.8 я использую:

variable salida refcursor
exec MY_PKG.MY_PRC(1, 2, 3, :salida)  -- 1, 2, 3 are params
print salida

затем выполните как скрипт.

3
create or replace procedure my_proc(  v_number IN number,p_rc OUT SYS_REFCURSOR )
as
begin
open p_rc
for select 1 col1
     from dual;
 end;
 /

а затем напишите функцию lie, которая вызывает вашу хранимую процедуру

 create or replace function my_proc_test(v_number IN NUMBER) RETURN sys_refcursor
 as
 p_rc sys_refcursor;
 begin
 my_proc(v_number,p_rc);
 return p_rc;
 end
 /

затем вы можете запустить этот SQL-запрос в Редакторе SQLDeveloper.

 SELECT my_proc_test(3) FROM DUAL;

вы увидите результат в консоли щелкните правой кнопкой мыши на нем и cilck на одной записи просмотра и редактировать результат вы можете увидеть все записи, которые были возвращены курсором ref.

2

Я думаю, что этой ссылки будет достаточно для вас. Я нашел его, когда искал способ выполнения процедур oracle.

ссылка на страницу

Краткое Описание:

--cursor variable declaration 
variable Out_Ref_Cursor refcursor;
--execute procedure 
execute get_employees_name(IN_Variable,:Out_Ref_Cursor);
--display result referenced by ref cursor.
print Out_Ref_Cursor;
-1