Как сделать правила сборки в cmake для предварительной обработки ленивого C++.lzz файлы, которые генерируют.h и.cpp файлов?

то, что я хотел бы сделать, это написать просто ленивый C++ .lzz файлы, а затем запустить lzz перед сборкой для создания .cpp и .H файлы, которые будут встроены в конечное приложение, вроде того, как moc работает с Qt.

есть ли способ сделать это?

8
cmake lazy-c++

3 ответов

вот пример того, как это сделать... Сначала вам нужно найти lzz программа, для этого используйте find_program команда:

find_program(LZZ_COMMAND lzz)

установка LZZ_COMMAND к пути компилятора. Затем используйте пользовательскую команду CMake для компиляции файла LZZ в файлы заголовка / реализации C++:

add_custom_command(
    OUTPUT ${output}
    COMMAND ${LZZ_COMMAND} -o ${CMAKE_CURRENT_BINARY_DIR} ${filename})

который генерирует файлы в текущем каталоге сборки, в случае, если вы делаете сборки вне источника. Вам также нужно будет указать, что выходные данные генерируются файлы:

set_source_files_properties(${output} PROPERTIES GENERATED TRUE)

положите все это вместе, и вы получите CMakeLists.txt файл что-то вроде этого:

cmake_minimum_required(VERSION 2.8)
project(lazy_test)
find_program(LZZ_COMMAND lzz)
function(lazy_compile filename)
    get_filename_component(base ${filename} NAME_WE)
    set(base_abs ${CMAKE_CURRENT_BINARY_DIR}/${base})
    set(output ${base_abs}.cpp ${base_abs}.h)
    add_custom_command(
        OUTPUT ${output}
        COMMAND ${LZZ_COMMAND} -o ${CMAKE_CURRENT_BINARY_DIR} ${filename})
    set_source_files_properties(${output} PROPERTIES GENERATED TRUE)
endfunction()
lazy_compile(${CMAKE_CURRENT_SOURCE_DIR}/example.lzz)
add_executable(test example.cpp example.h)

вы, вероятно, также захотите добавить include path и другие параметры в lzz в конечном итоге. Если вы поместили все ленивые материалы C++ в файл модуля и включили это из CMakeLists.txt было бы немного чище. Но это основная идея.

8

Я просто хотел поделиться своими CMakeLists.txt, который основан на сценарии richq. Этот.* cpp и *.файлы hpp теперь правильно зависят от *.lzz файлов. Этот.* lzz файлы добавляются в проект (какие ответы, если вопрос выше), но отдельно от файлов, созданных с помощью source_group команды.

единственным оставшимся dealbreaker для меня является невозможность скомпилировать текущий файл для *.lzz файлов.

cmake_minimum_required(VERSION 2.8)

PROJECT(LzzTest)

find_program(LZZ_COMMAND lzz.exe)

# Syntax: 
#   add_lzz_file(<output> <lzz file>)
# Adds a build rule for the specified lzz file. The absolute paths of the generated 
# files are added to the <output> list. The files are generated in the binary dir.
# 
# TODO: Support for generating template files etc.
function(add_lzz_file output filename)
  # Only process *.lzz files
  get_filename_component(ext ${filename} EXT)
  if(NOT ext STREQUAL ".lzz")
    return()
  endif()

  set(header_extension "hpp")
  get_filename_component(base ${filename} NAME_WE)
  set(base_abs ${CMAKE_CURRENT_BINARY_DIR}/${base})
  set(outfiles ${base_abs}.cpp ${base_abs}.${header_extension})
  set(${output} ${${output}} ${outfiles} PARENT_SCOPE)

  #message("outfiles=${outfiles}, DEPENDS ${CMAKE_CURRENT_SOURCE_DIR}/${filename}")
  add_custom_command(
    OUTPUT ${outfiles}
    COMMAND ${LZZ_COMMAND} 
      -o ${CMAKE_CURRENT_BINARY_DIR} # output dir
      -hx ${header_extension}
      -sl -hl -il -tl -nl -x # insert #line commands w/ absolute paths
      -sd -hd -id -td -nd # don't output files that didn't change
      ${CMAKE_CURRENT_SOURCE_DIR}/${filename}
    DEPENDS "${CMAKE_CURRENT_SOURCE_DIR}/${filename}"
  )

  set_source_files_properties(${outfiles} PROPERTIES GENERATED TRUE)
endfunction()

include_directories(${CMAKE_CURRENT_BINARY_DIR})

set(SOURCES
  A.lzz
  B.lzz
  main.cpp
)

foreach(file ${SOURCES})
  add_lzz_file(GENERATED_SOURCES ${file})
endforeach()

source_group("" FILES ${SOURCES})
source_group(generated FILES ${GENERATED_SOURCES})

add_executable(LzzTest ${SOURCES} ${GENERATED_SOURCES})
4

для make:

sourcecode.h sourcecode.cpp: sourcecode.lzz
<TAB>lazy-cpp sourcecode.lzz

заполнить исходник.ч, исходный код.cpp и lazy-cpp с правильными значениями. Я их не знаю.

-1