Как удалить несколько буферов в Vim?
предполагая, что у меня есть несколько файлов, открытых в качестве буферов в Vim. Файлы *.cpp
, *.h
и несколько *.xml
. Я хочу закрыть все XML-файлы с помощью :bd *.xml
. Однако Vim не позволяет этого (E93: более одного матча...).
есть ли способ сделать это?
P. S. Я знаю, что :bd file1 file2 file3
строительство. Так что я могу как-то оценить *.xml
to file1.xml file2.xml file3.xml
?
8 ответов
можно использовать <C-a>
для завершения всех матчей. Поэтому, если вы наберете :bd *.xml
и затем нажмите <C-a>
, vim завершит команду :bd file1.xml file2.xml file3.xml
.
вы также можете использовать альтернативно использовать:
:.,$-bd[elete] " to delete buffers from the current one to last but one
:%bd[elete] " to delete all buffers
Вы можете использовать это.
:exe 'bd '. join(filter(map(copy(range(1, bufnr('$'))), 'bufname(v:val)'), 'v:val =~ "\.xml$"'), ' ')
это должно быть довольно легко добавить его в команду.
function! s:BDExt(ext)
let buffers = filter(range(1, bufnr('$')), 'buflisted(v:val) && bufname(v:val) =~ "\.'.a:ext.'$"')
if empty(buffers) |throw "no *.".a:ext." buffer" | endif
exe 'bd '.join(buffers, ' ')
endfunction
command! -nargs=1 BDExt :call s:BDExt(<f-args>)
попробуйте сценарий ниже. Пример для "txt", измените его по мере необходимости, например, на"xml". Измененные буферы не удаляются. Нажмите \bd, чтобы удалить буферы.
map <Leader>bd :bufdo call <SID>DeleteBufferByExtension("txt")
function! <SID>DeleteBufferByExtension(strExt)
if (matchstr(bufname("%"), ".".a:strExt."$") == ".".a:strExt )
if (! &modified)
bd
endif
endif
endfunction
[Edit] Же без :bufdo (по просьбе Люка Hermitte, см. комментарий ниже)
map <Leader>bd :call <SID>DeleteBufferByExtension("txt")
function! <SID>DeleteBufferByExtension(strExt)
let s:bufNr = bufnr("$")
while s:bufNr > 0
if buflisted(s:bufNr)
if (matchstr(bufname(s:bufNr), ".".a:strExt."$") == ".".a:strExt )
if getbufvar(s:bufNr, '&modified') == 0
execute "bd ".s:bufNr
endif
endif
endif
let s:bufNr = s:bufNr-1
endwhile
endfunction
у меня тоже была потребность в этой функциональности все время. Это решение у меня в vimrc.
function! GetBufferList()
return filter(range(1,bufnr('$')), 'buflisted(v:val)')
endfunction
function! GetMatchingBuffers(pattern)
return filter(GetBufferList(), 'bufname(v:val) =~ a:pattern')
endfunction
function! WipeMatchingBuffers(pattern)
let l:matchList = GetMatchingBuffers(a:pattern)
let l:count = len(l:matchList)
if l:count < 1
echo 'No buffers found matching pattern ' . a:pattern
return
endif
if l:count == 1
let l:suffix = ''
else
let l:suffix = 's'
endif
exec 'bw ' . join(l:matchList, ' ')
echo 'Wiped ' . l:count . ' buffer' . l:suffix . '.'
endfunction
command! -nargs=1 BW call WipeMatchingBuffers('<args>')
теперь, я могу просто сделать :BW regex
(например,:BW \.cpp$
и удалить все соответствующие буферы, которые соответствуют этому шаблону в их пути.
если вы хотите удалить, а не стереть, вы можете, конечно, заменить exec 'bw ' . join(l:matchList, ' ')
С exec 'bd ' . join(l:matchList, ' ')
TAB
будет только автозаполнение одного файла для вас с Vim 7.4.282
использовать<c-a>
для автозаполнения всех файлов.
вы можете просто использовать:
bd filetype
затем просто использовать <c-a>
для облегчения завершения всех открытых файлов указанного типа файлов.
например, у вас есть 1.формате XML, 2.XML-файле, 3.xml и 4.XML, вы можете сделать:
bd xml
нажмите клавишу <c-a>
vim будет автозаполнение для вас как следуйте:
bd 1.xml 2.xml 3.xml 4.xml
вы можете просто нажать enter, чтобы завершить команду.
если вы внесли изменения в один из файлов, упомянутых выше, не забудьте сделать:
bd! xml