Как удалить пробелы из имен файлов (оптом)

Как удалить пробелы (не заменять подчеркивания) из нескольких тысяч файлов навалом в Windows? Могу ли я сделать это из команды DOS?

: 
file one.mp3
file two.mp3

все файлы должны стать:

fileone.mp3
filetwo.mp3
17
batch-file renaming windows

5 ответов

вот скрипт, который может эффективно массово переименовывать файлы, удаляя все пробелы из имени.

:renameNoSpace  [/R]  [FolderPath]
@echo off
setlocal disableDelayedExpansion
if /i "%~1"=="/R" (
  set "forOption=%~1 %2"
  set "inPath="
) else (
  set "forOption="
  if "%~1" neq "" (set "inPath=%~1\") else set "inPath="
)
for %forOption% %%F in ("%inPath%* *") do (
  if /i "%~f0" neq "%%~fF" (
    set "folder=%%~dpF"
    set "file=%%~nxF"
    setlocal enableDelayedExpansion
    echo ren "!folder!!file!" "!file: =!"
    ren "!folder!!file!" "!file: =!"
    endlocal
  )
)

предположим, что скрипт называется renameNoSpace.летучая мышь!--10-->

renameNoSpace : (без аргументов) переименовывает файлы в текущем каталоге

renameNoSpace /R: переименовывает файлы в дереве папок, укорененных в текущем каталоге

renameNoSpace myFolder: переименовывает файлы в каталоге "myFolder", найденном в текущем каталоге.

renameNoSpace "c:\my folder\" : Переименовывает файлы по указанному пути. Кавычки используются, потому что path содержит пробел.

renameNoSpace /R c:\ : переименовывает все файлы на диске C:.

62

создать файл powershell -*.ps1 расширение

пишем этот код:

dir |
Where-Object { $_.name.Contains(" ") } |
Rename-Item -NewName { $_.name -replace " ","" }

сохранить, затем щелкните правой кнопкой мыши - > выполнить с помощью powershell

8
@echo off
setlocal enableextensions enabledelayedexpansion

for %%f in (*.*) do (
set ARG=%%~nxf
rename "%%f" !ARG: =!
)
4

Вы можете написать простой скрипт, который делает это для одного файла/каталога, например:

@echo off
setlocal enableextensions enabledelayedexpansion

set "ARG=%~1"
ren "%ARG%" "%ARG: =%"

...а затем, если хотите, запустите его по всем файлам и / или каталогам, о которых вы заботитесь. Например, если вы создадите вышеуказанный скрипт как myrenamingscript.cmd, вы можете запустить его над всеми файлами без dir в текущем dir, выполнив:

for %f in (*) do @myrenamingscript.cmd "%~f"
3

проблема, с которой я столкнулся, заключается в том, что существует вероятность того, что уже есть файл с именем, которое вы пытаетесь дать новому файлу (например, если в папке с именем "файл один" есть 2 файла.txt " и " file_one.txt " при попытке заменить пробелы символами подчеркивания один файл заменит другой). Поэтому я сделал этот скрипт, который проверяет, существует ли новое имя, и если да, то помещает номер в конец имени файла (добавляет 1 к номеру, пока нет другого файла с этим именем). Инструкции о том, что изменить, находятся вверху (рекомендуемые строки). Не храните пакетный файл в той же папке, в которой у вас есть файлы для переименования, если вы используете *.* опцион. Надеюсь, это поможет.

@echo off

REM Instructions
REM This script repaces spaces from file names with underscores. 
REM If you want to just remove the spaces uncomment lines 30 and 52 and comment out the lines 29 and 51. 
REM set the following parameters. 
REM pb is the folder containing the files we want to rename (fullpath)
REM tm is a temporary folder that will be created and deleted. Just put a folder that does not exist and is not used by anything else (fullpath).
REM all is the file type you want to raname. E.g. *.* for every file, *.txt for TXTs, *.pdf for PDFs etc 
REM you don't have to change anything else

set pb=<folder containing the files to rename>
set tm=<a temp folder that does not exist>
set all=*.*

set pa=%pb%%all%

setlocal EnableDelayedExpansion

cd /d %pa%

set /a count=1

if not exist %tm% mkdir %tm%

for /f %%F in (%pa%) do (

    set name=%%~nF
    set name2=!name: =_!
    REM set name2=!name: =!
    set name3=!name2!%%~xF

    if !name2! == %%~nF ( 
        move /y %%~dpF\!name3! %tm%\ >nul
    ) else (
            if not exist %%~dpF\!name3! ( 
                if not exist %tm%\!name3! (
                    ren "%%F" "!name3!" 
                    move /y %%~dpF\!name3! %tm%\ >nul
                )
        )   
    ) 

)

:rename

for /f %%F in (%pa%) do (

    set name=%%~nF
    set name2=!name: =_!
    REM set name2=!name: =!
    set name4=!name2!%count%
    set name3=!name4!%%~xF

    if !name2! == %%~nF ( 
        move /y %%~dpF\!name3! %tm%\ >nul
    ) else (
            if not exist %%~dpF\!name3! ( 
                if not exist %tm%\!name3! (
                    ren "%%F" "!name3!" 
                    move /y %%~dpF\!name3! %tm%\ >nul
                )
        )   
    ) 

)

set /a count = %count% + 1

set /a loop = 0

for %%F in (%pa%) do (set /a loop = 1)

if %loop% equ 1 goto rename

move /y %tm%\%all% %pb% >nul

rmdir /s /q %tm%
0