Как вернуть результат из функции VBA

Как вернуть результат из функции?

например:

Public Function test() As Integer
    return 1
End Function

Это дает ошибку при компиляции.

Как сделать так, чтобы эта функция возвращала целое число?

217
excel excel-vba function result vba

4 ответов

для типов возврата без объекта вы должны присвоить значение имени своей функции, например:

Public Function test() As Integer
    test = 1
End Function

пример использования:

Dim i As Integer
i = test()

если функция возвращает тип объекта, то вы должны использовать Set ключевое слово вроде этого:

Public Function testRange() As Range
    Set testRange = Range("A1")
End Function

пример использования:

Dim r As Range
Set r = testRange()

обратите внимание, что присвоение возвращаемого значения имени функции не завершает выполнение вашей функции. Если вы хотите выйти из функции, то нужно явно скажите Exit Function. Например:

Function test(ByVal justReturnOne As Boolean) As Integer
    If justReturnOne Then
        test = 1
        Exit Function
    End If
    'more code...
    test = 2
End Function

документация: http://msdn.microsoft.com/en-us/library/office/gg264233%28v=office.14%29.aspx

338

функции VBA рассматривают само имя функции как своего рода переменную. Поэтому вместо использования "

78

просто установка возвращаемого значения имени функции по-прежнему не ровно то же самое, что и Java (или другое) return заявление, потому что в java,return завершает работу функции следующим образом:

public int test(int x) {
    if (x == 1) {
        return 1; // exits immediately
    }

    // still here? return 0 as default.
    return 0;
}

в VB,точно эквивалент занимает две строки если вы не устанавливаете возвращаемое значение в конце вашей функции. Итак, в VB точное следствие будет выглядеть следующим образом: 

Public Function test(ByVal x As Integer) As Integer
    If x = 1 Then
        test = 1 ' does not exit immediately. You must manually terminate...
        Exit Function ' to exit
    End If

    ' Still here? return 0 as default.
    test = 0
    ' no need for an Exit Function because we're about to exit anyway.
End Function

поскольку это так, это также приятно знать, что вы можете использовать возвращаемую переменную, как и любую другую переменную в методе. Вот так:

Public Function test(ByVal x As Integer) As Integer

    test = x ' <-- set the return value

    If test <> 1 Then ' Test the currently set return value
        test = 0 ' Reset the return value to a *new* value
    End If

End Function

или, по крайней пример как вернуть переменную работает (но не обязательно хороший пример того, как вы должны на самом деле код) - тот, который будет держать вас ночью: 

Public Function test(ByVal x As Integer) As Integer

    test = x ' <-- set the return value

    If test > 0 Then

        ' RECURSIVE CALL...WITH THE RETURN VALUE AS AN ARGUMENT,
        ' AND THE RESULT RESETTING THE RETURN VALUE.
        test = test(test - 1)

    End If

End Function
29

приведенный ниже код хранит возвращаемое значение в переменной retVal а то MsgBox может использоваться для отображения значения:

Dim retVal As Integer
retVal = test()
Msgbox retVal
-3