Как выбрать наименьшее значение из группы переменных?

Предположим, у меня есть переменные $a, $b, $c и $d которые все держат номера. Хотелось бы получить наименьшее (наибольшее) значение. Мой типичный подход XSLT 1.0 к этому -

<xsl:variable name="minimum">
  <xsl:for-each select="$a | $b | $c | $d">
    <xsl:sort
      select="."
      data-type="number"
      order="ascending" />
    <xsl:if test="position()=1"><xsl:value-of select="." /></xsl:if>
  </xsl:for-each>
</xsl:variable>

однако, мой xslt 1.0 ругается с

Ошибка времени выполнения: файл stylesheet.элемент XSLT line 106 для-each
Выражение "select" не вычисляется для набора узлов.

как я могу вычислить минимальный (максимум) заданных значений?

конечно, я мог бы использовать длинный ряд <xsl:when> заявления и проверьте все комбинации, но я бы предпочел меньшее решение.

6
minimum xslt xslt-1.0

3 ответов

если переменные имеют статически определенные значения (не динамически вычисляемые), то с помощью XSLT 1.0:

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output method="text"/>

 <xsl:variable name="vA" select="3"/>
 <xsl:variable name="vB" select="1"/>
 <xsl:variable name="vC" select="9"/>
 <xsl:variable name="vD" select="5"/>

 <xsl:template match="/">
     <xsl:for-each select=
      "document('')/*/xsl:variable
         [contains('|vA|vB|vC|vD|', concat('|', @name, '|'))]
           /@select
      ">
      <xsl:sort data-type="number" order="ascending"/>

      <xsl:if test="position() = 1">
       Smallest: <xsl:value-of select="."/>
      </xsl:if>
      <xsl:if test="position() = last()">
       Largest: <xsl:value-of select="."/>
      </xsl:if>
     </xsl:for-each>
 </xsl:template>
</xsl:stylesheet>

когда это преобразование применяется к любому XML-документу (не используется), получается нужный, правильный результат:

   Smallest: 1
   Largest: 9

II. Теперь предположим, что переменные динамически определены.

мы можем сделать что-то подобное (но нужно the xxx:node-set() функции расширения):

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
 xmlns:ext="http://exslt.org/common">
 <xsl:output method="text"/>

 <xsl:variable name="vA" select="number(/*/*[3])"/>
 <xsl:variable name="vB" select="number(/*/*[1])"/>
 <xsl:variable name="vC" select="number(/*/*[9])"/>
 <xsl:variable name="vD" select="number(/*/*[5])"/>

 <xsl:template match="/">
     <xsl:variable name="vrtfStore">
       <num><xsl:value-of select="$vA"/></num>
       <num><xsl:value-of select="$vB"/></num>
       <num><xsl:value-of select="$vC"/></num>
       <num><xsl:value-of select="$vD"/></num>
     </xsl:variable>

     <xsl:for-each select="ext:node-set($vrtfStore)/*">
      <xsl:sort data-type="number" order="ascending"/>

      <xsl:if test="position() = 1">
       Smallest: <xsl:value-of select="."/>
      </xsl:if>
      <xsl:if test="position() = last()">
       Largest: <xsl:value-of select="."/>
      </xsl:if>
     </xsl:for-each>
 </xsl:template>
</xsl:stylesheet>

когда это преобразование применяется к следующему XML-документу:

<nums>
  <num>01</num>
  <num>02</num>
  <num>03</num>
  <num>04</num>
  <num>05</num>
  <num>06</num>
  <num>07</num>
  <num>08</num>
  <num>09</num>
  <num>10</num>
</nums>

получается нужный, правильный результат:

   Smallest: 1
   Largest: 9
5

это решение XSLT 1.0 использует рекурсивные шаблоны для анализа списка значений с разделителями для возврата значения min / max из списка.

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>

   <xsl:variable name="a" select="'3'"/>
    <xsl:variable name="b" select="'1'"/>
    <xsl:variable name="c" select="'9'"/>
    <xsl:variable name="d" select="'5'"/>

    <xsl:template match="/">
        <xsl:text>&#xa;Smallest: </xsl:text>
        <xsl:call-template name="min">
            <xsl:with-param name="values" select="concat($a,',',$b,',',$c,',',$d)"/>    
        </xsl:call-template>

        <xsl:text>&#xa;Largest: </xsl:text>
        <xsl:call-template name="max">
            <xsl:with-param name="values" select="concat($a,',',$b,',',$c,',',$d)"/>    
        </xsl:call-template>
    </xsl:template>

    <xsl:template name="min">
        <xsl:param name="values" />
        <xsl:param name="delimiter" select="','"/>
        <xsl:param name="min"/>

        <xsl:variable name="currentValue" >
            <xsl:choose>
                <xsl:when test="contains($values, $delimiter)">
                    <xsl:value-of select="substring-before($values,$delimiter)"/>
                </xsl:when>
                <xsl:otherwise>
                    <xsl:value-of select="$values"/>
                </xsl:otherwise>
            </xsl:choose>
        </xsl:variable>

        <xsl:variable name="minimumValue">
            <xsl:choose>
                <xsl:when test="$min and $min > $currentValue">
                    <xsl:value-of select="$currentValue"/>
                </xsl:when>
                <xsl:when test="$min">
                    <xsl:value-of select="$min"/>
                </xsl:when>
                <xsl:otherwise>
                    <xsl:value-of select="$currentValue" />
                </xsl:otherwise>
            </xsl:choose>
        </xsl:variable>

       <xsl:choose>
            <xsl:when test="substring-after($values,$delimiter)">
                <xsl:call-template name="min">
                    <xsl:with-param name="min" select="$minimumValue" />
                    <xsl:with-param name="values" select="substring-after($values,$delimiter)" />
                    <xsl:with-param name="delimiter" select="$delimiter"/>
                </xsl:call-template>
            </xsl:when>
            <xsl:otherwise>
                <xsl:value-of select="$minimumValue" />
            </xsl:otherwise>
        </xsl:choose>                
    </xsl:template>


    <xsl:template name="max">
        <xsl:param name="values" />
        <xsl:param name="delimiter" select="','"/>
        <xsl:param name="max"/>

        <xsl:variable name="currentValue" >
            <xsl:choose>
                <xsl:when test="contains($values, $delimiter)">
                    <xsl:value-of select="substring-before($values,$delimiter)"/>
                </xsl:when>
                <xsl:otherwise>
                    <xsl:value-of select="$values"/>
                </xsl:otherwise>
            </xsl:choose>
        </xsl:variable>

        <xsl:variable name="maximumValue">
            <xsl:choose>
                <xsl:when test="$max and $currentValue > $max">
                    <xsl:value-of select="$currentValue"/>
                </xsl:when>
                <xsl:when test="$max">
                    <xsl:value-of select="$max"/>
                </xsl:when>
                <xsl:otherwise>
                    <xsl:value-of select="$currentValue" />
                </xsl:otherwise>
            </xsl:choose>
        </xsl:variable>

        <xsl:choose>
            <xsl:when test="substring-after($values,$delimiter)">
                <xsl:call-template name="max">
                    <xsl:with-param name="max" select="$maximumValue" />
                    <xsl:with-param name="values" select="substring-after($values,$delimiter)" />
                    <xsl:with-param name="delimiter" select="$delimiter"/>
                </xsl:call-template>
            </xsl:when>
            <xsl:otherwise>
                <xsl:value-of select="$maximumValue" />
            </xsl:otherwise>
        </xsl:choose>                
    </xsl:template>
</xsl:stylesheet>

при выполнении, производит следующий вывод:

Smallest: 1
Largest: 9
3

Мне никогда не приходилось делать это в 1.0 (я использую 2.0), но вы могли бы сделать это:

  <xsl:variable name="minimum">
    <xsl:choose>
      <xsl:when test="$b > $a and $c > $a and $d > $a"><xsl:value-of select="$a"/></xsl:when>
      <xsl:when test="$a > $b and $c > $b and $d > $b"><xsl:value-of select="$b"/></xsl:when>
      <xsl:when test="$b > $c and $a > $c and $d > $c"><xsl:value-of select="$c"/></xsl:when>
      <xsl:when test="$b > $d and $c > $d and $a > $d"><xsl:value-of select="$d"/></xsl:when>
    </xsl:choose>
  </xsl:variable>

должен быть лучший способ.

1