Преобразование XML в обычный текст-как игнорировать / обрабатывать пробелы в XSLT?

вы используете indent= " no " в своем выходном теге?

<xsl:output method="text" indent="no" />

также, если вы используете xsl: value-of вы можете использовать disable-output-escaping= "yes", чтобы помочь с некоторыми проблемами пробелов.

ответ@JeniT отличный, я просто хочу указать на трюк для управления пробелами. Я не уверен, что это лучший способ (или даже хороший способ), но это работает для меня сейчас.

("С" - пространство, "е" - пустой, "н" для перехода на новую строку.)

<?xml version="1.0" encoding="UTF-8"?>
<!DOCTYPE xsl:transform [
  <!ENTITY s "<xsl:text xmlns:xsl='http://www.w3.org/1999/XSL/Transform'> </xsl:text>" >
  <!ENTITY s2 "<xsl:text xmlns:xsl='http://www.w3.org/1999/XSL/Transform'>  </xsl:text>" >
  <!ENTITY s4 "<xsl:text xmlns:xsl='http://www.w3.org/1999/XSL/Transform'>    </xsl:text>" >
  <!ENTITY s6 "<xsl:text xmlns:xsl='http://www.w3.org/1999/XSL/Transform'>      </xsl:text>" >
  <!ENTITY e "<xsl:text xmlns:xsl='http://www.w3.org/1999/XSL/Transform'></xsl:text>" >
  <!ENTITY n "<xsl:text xmlns:xsl='http://www.w3.org/1999/XSL/Transform'>
</xsl:text>" >
]>

<xsl:transform version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:xs="http://www.w3.org/2001/XMLSchema">
<xsl:output method="text"/>
<xsl:template match="/">
  &e;Flush left, despite the indentation.&n;
  &e;  This line will be output indented two spaces.&n;

      <!-- the blank lines above/below won't be output -->

  <xsl:for-each select="//foo">
    &e;  Starts with two blanks: <xsl:value-of select="@bar"/>.&n;
    &e;  <xsl:value-of select="@baz"/> The 'e' trick won't work here.&n;
    &s2;<xsl:value-of select="@baz"/> Use s2 instead.&n;
    &s2;    <xsl:value-of select="@abc"/>    <xsl:value-of select="@xyz"/>&n;
    &s2;    <xsl:value-of select="@abc"/>&s;<xsl:value-of select="@xyz"/>&n;
  </xsl:for-each>
</xsl:template>
</xsl:transform>

применяется для:

<?xml version="1.0" encoding="UTF-8"?>
<foo bar="bar" baz="baz" abc="abc" xyz="xyz"></foo>

выходы:

Flush left, despite the indentation.
  This line will be output indented two spaces.
  Starts with two blanks: bar.
baz The 'e' trick won't work here.
  baz Use s2 instead.
  abcxyz
  abc xyz

трюк " e " работает до текстового узла, содержащего по крайней мере один символ без пробелов, потому что он расширяется до этого:

<xsl:template match="/">
  <xsl:text></xsl:text>Flush left, despite the indentation.<xsl:text>
</xsl:text>

С the правила зачистки пробелов скажем, что текстовые узлы только с пробелами удаляются, новая строка и отступ между

проблема у меня есть, когда я хочу вывести отступ, который начинается с . В этом случае "&e;" не поможет, потому что пробелы отступа не "прикреплены" к любым символам, не являющимся пробелами. Поэтому для этих случаев я использую " &s2;" или " &s4;", в зависимости от того, сколько отступов я хочу.

это уродливый Хак, я уверен, но, по крайней мере, у меня нет многословия " " теги, усеивающие мой XSLT, и, по крайней мере, я все еще могу отступить от самого XSLT, чтобы он был разборчив. Я чувствую, что злоупотребляю XSLT для чего-то, для чего он не был разработан (обработка текста), и это лучшее, что я могу сделать.

Edit: В ответ на комментарии, вот как это выглядит без "макросов":

<xsl:template match="/">
  <xsl:text>Flush left, despite the indentation.</xsl:text>
  <xsl:text>  This line will be output indented two spaces.</xsl:text>
  <xsl:for-each select="//foo">
    <xsl:text>  Starts with two blanks: </xsl:text><xsl:value-of select="@bar"/>.<xsl:text>
</xsl:text>
    <xsl:text>    </xsl:text><xsl:value-of select="@abc"/><xsl:text> </xsl:text><xsl:value-of select="@xyz"/><xsl:text>
</xsl:text>
  </xsl:for-each>
</xsl:template>

Я думаю, что это делает его менее ясным, чтобы увидеть предполагаемый выходной отступ, и он закручивает отступ самого XSL потому что </xsl:text> конечные теги должны отображаться в столбце 1 файла XSL (в противном случае вы получите нежелательные пробелы в выходном файле).

Что касается редактирования новых строк, вы можете использовать этот шаблон для рекурсивной замены одной строки в другой строке, и вы можете использовать его для разрывов строк:

<xsl:template name="replace.string.section">
  <xsl:param name="in.string"/>
  <xsl:param name="in.characters"/>
  <xsl:param name="out.characters"/>
  <xsl:choose>
    <xsl:when test="contains($in.string,$in.characters)">
      <xsl:value-of select="concat(substring-before($in.string,$in.characters),$out.characters)"/>
      <xsl:call-template name="replace.string.section">
        <xsl:with-param name="in.string" select="substring-after($in.string,$in.characters)"/>
        <xsl:with-param name="in.characters" select="$in.characters"/>
        <xsl:with-param name="out.characters" select="$out.characters"/>
      </xsl:call-template>
    </xsl:when>
    <xsl:otherwise>
      <xsl:value-of select="$in.string"/>
    </xsl:otherwise>
  </xsl:choose>
</xsl:template> 

вызовите его следующим образом (этот пример заменяет разрывы строк в $some.строковая переменная с пробелом):

    <xsl:call-template name="replace.string.section">
        <xsl:with-param name="in.string" select="$some.string"/>
        <xsl:with-param name="in.characters" select="'&#xA;'"/>
        <xsl:with-param name="out.characters" select="' '"/>
    </xsl:call-template>