QML изменение цвета изображения

Я искал, как раскрасить изображение (с форматом svg или png ...).

Я попытался покрыть свое изображение прямоугольником, который заполняет изображение, но поскольку мое изображение не является прямоугольником, оно окрашивает весь прямоугольник, а не только изображение.

можно ли изменить цвет изображения с помощью qml? Кроме того, можно ли изменить цвет на qt (с C++) с помощью QPixmap, а затем интегрировать QPixmap в элемент QML?

Спасибо за помощь. (Если есть нет решения, мне придется загрузить другое изображение в одно и то же базовое изображение с другим цветом.)

10
colors image qml qt svg

2 ответов

вы можете использовать ColorOverlay из Qt 5.2 следующим образом:

import QtQuick 2.0
import QtGraphicalEffects 1.0

Item {
    width: 300
    height: 300

    Image {
        id: bug
        source: "images/butterfly.png"
        sourceSize: Qt.size(parent.width, parent.height)
        smooth: true
        visible: false
    }

    ColorOverlay {
        anchors.fill: bug
        source: bug
        color: "#ff0000"  // make image like it lays under red glass 
    }
 }
13

вы можете заменить цвет изображения с помощью ShaderEffect.

ShaderEffect {
    property variant src: yourImage

    property real r: yourColor.r * yourColor.a
    property real g: yourColor.g * yourColor.a
    property real b: yourColor.b * yourColor.a

    width: yourImage.width
    height: yourImage.height

    vertexShader: "
        uniform highp mat4 qt_Matrix;
        attribute highp vec4 qt_Vertex;
        attribute highp vec2 qt_MultiTexCoord0;
        varying highp vec2 coord;

        void main() {
            coord = qt_MultiTexCoord0;
            gl_Position = qt_Matrix * qt_Vertex;
        }
    "

    fragmentShader: "
        varying highp vec2 coord;
        uniform sampler2D src;

        uniform lowp float r;
        uniform lowp float g;
        uniform lowp float b;

        void main() {
            lowp vec4 clr = texture2D(src, coord);
            lowp float avg = (clr.r + clr.g + clr.b) / 3.;
            gl_FragColor = vec4(r * avg, g * avg, b * avg, clr.a);
        }
    "
}

приведенный выше код превращает ваше изображение в оттенки серого, а затем применяет ваш цвет.

3