С emacs, как вы меняете положение 2 окон

У меня открыто 2 окна в Emacs, и я хотел бы поменять их позиции.

Ie рассмотрите возможность иметь REPL выше исходного файла, и я хотел бы поменять местами их расположения, чтобы REPL был ниже исходного файла.

Я также хотел бы сохранить размеры окон

9
emacs

4 ответов

я бесстыдно украл это у Стив Yegge по .в Emacs

(defun swap-windows ()
  "If you have 2 windows, it swaps them." 
  (interactive)
  (cond ((not (= (count-windows) 2)) (message "You need exactly 2 windows to do this."))
        (t
         (let* ((w1 (first (window-list)))
                (w2 (second (window-list)))
                (b1 (window-buffer w1))
                (b2 (window-buffer w2))
                (s1 (window-start w1))
                (s2 (window-start w2)))
           (set-window-buffer w1 b2)
           (set-window-buffer w2 b1)
           (set-window-start w1 s2)
           (set-window-start w2 s1)))))

протестировано на Emacs 23.1.1 на Gentoo. Это сохраняет размеры окон.

Я также нашел, что это немного чище.

(defun transpose-windows ()
  (interactive)
  (let ((this-buffer (window-buffer (selected-window)))
        (other-buffer (prog2
                          (other-window +1)
                          (window-buffer (selected-window))
                        (other-window -1))))
    (switch-to-buffer other-buffer)
    (switch-to-buffer-other-window this-buffer)
    (other-window -1)))

также протестировано на Emacs 23.1.1

7

следующая версия работает с любым количеством окон. При наличии более двух окон повторные вызовы заставят выбранный буфер отображаться в каждом окне последовательно.

(defun swap-buffer ()
  (interactive)
  (cond ((one-window-p) (display-buffer (other-buffer)))
        ((let* ((buffer-a (current-buffer))
                (window-b (cadr (window-list)))
                (buffer-b (window-buffer window-b)))
           (set-window-buffer window-b buffer-a)
           (switch-to-buffer buffer-b)
           (other-window 1)))))
4

найти TransposeFrame библиотека полезных. Я!--3-->в основном используйте его для замены двух окон, согласно этому вопросу; но он обеспечивает более общую функциональность, чем просто это.

перейдите по ссылке, чтобы увидеть ascii-диаграммы различных преобразований.

2

см.http://www.emacswiki.org/cgi-bin/wiki/buffer-move.el. Вы можете установить его через elpa

1