Создание экземпляра Read в Haskell

Я буду использовать isDigit и держите свое определение времени.

import Data.Char (isDigit)

data Time = Time {hour :: Int,
                  minute :: Int
                 }

вы использовали, но не определяют newTime, поэтому я написал один сам, поэтому мой код компилируется!

newTime :: Int -> Int -> Time
newTime h m | between 0 23 h && between 0 59 m = Time h m
            | otherwise = error "newTime: hours must be in range 0-23 and minutes 0-59"
     where between low high val = low <= val && val <= high

во-первых, ваш экземпляр шоу немного неправильно, потому что show $ Time 10 10 дает "010:010"

instance Show Time where
  show (Time hour minute) = (if hour > 9       -- oops
                             then (show hour)
                             else ("0" ++ show hour))
                            ++ ":" ++
                            (if minute > 9     -- oops
                             then (show minute)
                             else ("0" ++ show minute))

давайте посмотрим на readsPrec:

*Main> :i readsPrec
class Read a where
  readsPrec :: Int -> ReadS a
  ...
    -- Defined in GHC.Read
*Main> :i ReadS
type ReadS a = String -> [(a, String)]
    -- Defined in Text.ParserCombinators.ReadP

это парсер - он должен возвращать непревзойденную оставшуюся строку вместо просто "", так что вы правы, что the "" неправильно:

*Main> read "03:22" :: Time
03:22
*Main> read "[23:34,23:12,03:22]" :: [Time]
*** Exception: Prelude.read: no parse

он не может разобрать его, потому что вы выбросили ,23:12,03:22] в первом чтении.

давайте рефакторинг, что немного съесть вход, как мы идем вперед:

instance Read Time where
  readsPrec _ input =
    let (hours,rest1) = span isDigit input
        hour = read hours :: Int
        (c:rest2) = rest1
        (mins,rest3) = splitAt 2 rest2
        minute = read mins :: Int
        in
      if c==':' && all isDigit mins && length mins == 2 then -- it looks valid
         [(newTime hour minute,rest3)]
       else []                      -- don't give any parse if it was invalid

дает например

Main> read "[23:34,23:12,03:22]" :: [Time]
[23:34,23:12,03:22]
*Main> read "34:76" :: Time
*** Exception: Prelude.read: no parse

это, однако, позволяет "3: 45 "и интерпретирует его как"03:45". Я не уверен, что это хорошая идея, поэтому, возможно, мы могли бы добавить еще один тест length hours == 2.

Я собираюсь все это разделить и span вещи если мы делаем это таким образом, поэтому, возможно, я бы предпочел:

instance Read Time where
  readsPrec _ (h1:h2:':':m1:m2:therest) =
    let hour   = read [h1,h2] :: Int  -- lazily doesn't get evaluated unless valid
        minute = read [m1,m2] :: Int
        in
      if all isDigit [h1,h2,m1,m2] then -- it looks valid
         [(newTime hour minute,therest)]
       else []                      -- don't give any parse if it was invalid
  readsPrec _ _ = []                -- don't give any parse if it was invalid

что на самом деле кажется чище и проще.

на этот раз это не позволяет "3:45":

*Main> read "3:40" :: Time
*** Exception: Prelude.read: no parse
*Main> read "03:40" :: Time
03:40
*Main> read "[03:40,02:10]" :: [Time]
[03:40,02:10]