Таблицы интерферируют с переменными диапазона VBA в зависимости от области

объявление переменных уровня модуля просто для сохранения двух строк в каждом UDF, которые в противном случае потребовались бы, действительно плохая практика кодирования. Однако, если это ваше мышление, почему бы не пойти до конца и сохранить четыре строк в UDF, избегая задание их в каждом, Как хорошо!

вы можете сделать это, используя псевдо-постоянные функции, как показано в следующем коде:

Option Explicit

Private Function rng_ItemNumber() As Range
    Set rng_ItemNumber = Sheet1.Range("A4:A6")
End Function
Private Function rng_ItemName() As Range
    Set rng_ItemName = Sheet1.Range("B4:B6")
End Function

Public Function ITEM_NAME(varItemNumber As Variant) As String
' Returns Item Name as a function of Item Number.
  With Application.WorksheetFunction
    ITEM_NAME = .Index(rng_ItemName, .Match(varItemNumber, rng_ItemNumber))
  End With
End Function

стоимость, конечно, есть накладные расходы на вызов функции.

если вы планируете использовать ListObject класс для окончательного дизайна, тогда почему бы не использовать его сейчас,и используйте динамические именованные диапазоны (жестко закодированные диапазоны в примере есть, поэтому он фактически работает как есть - они должны быть заменены именованными диапазонами):

Option Explicit

Private Function str_Table1() As String
    Static sstrTable1 As String
    If sstrTable1 = vbNullString Then
      sstrTable1 = Sheet1.Range("A4:B6").ListObject.Name
    End If
    str_Table1 = sstrTable1
End Function
Private Function str_ItemNumber() As String
    Static sstrItemNumber As String
    If sstrItemNumber = vbNullString Then
      sstrItemNumber = Sheet1.Range("A4:A6").Offset(-1).Resize(1).Value2
    End If
    str_ItemNumber = sstrItemNumber
End Function
Private Function str_ItemName() As String
    Static sstrItemName As String
    If sstrItemName = vbNullString Then
      sstrItemName = Sheet1.Range("B4:B6").Offset(-1).Resize(1).Value2
    End If
    str_ItemName = sstrItemName
End Function

Public Function ITEM_NAME(varItemNumber As Variant) As String
  'Returns Item Name as a function of Item Number.
  Dim ƒ As WorksheetFunction: Set ƒ = WorksheetFunction
  With Sheet1.ListObjects(str_Table1)
    ITEM_NAME _
    = ƒ.Index _
      ( _
        .ListColumns(str_ItemName).DataBodyRange _
      , ƒ.Match(varItemNumber, .ListColumns(str_ItemNumber).DataBodyRange) _
      )
  End With
End Function

как только логика / дизайн будут готовы, вы можете заменить функции константами уровня модуля того же самого имя, если скорость критическая, и вам нужно восстановить накладные расходы вызова функции. В противном случае, вы можете просто оставить все как есть.

обратите внимание, что использование статических переменных не требуется, но необходимо сократить время выполнения. (Статические переменные также могли быть использованы в первом примере, но я оставил их, чтобы сохранить его коротким.)

вероятно, нет необходимости извлекать имена таблиц в псевдо-константы, но я сделал это для полноты сакэ.

EDIT: (v2)

следуя двум блестящим предложениям Egalth, приводит к следующему коду, который устраняет необходимость в именованных диапазонах,или даже жестко адреса ячеек, в целом, как мы используем встроенный динамизм самой таблицы ListObject.

я также изменил имя параметра, чтобы соответствовать * имя заголовка соответствующего столбца, поэтому, когда пользователь нажимает Ctrl+ Shift+A появится подсказка, какой столбец использовать. (Этот совет и, при необходимости, дополнительная информация о том, как добавить IntelliSense tool-tips и/или получить описание, чтобы появиться в диалоговом окне аргументы функции, можно увидеть здесь.)

Option Explicit

Private Function str_Table1() As String
    Static sstrTable1 As String
    If sstrTable1 = vbNullString Then sstrTable1 = Sheet1.ListObjects(1).Name ' or .ListObjects("Table1").Name
    str_Table1 = sstrTable1
End Function
Private Function str_ItemNumber() As String
    Static sstrItemNumber As String
    If sstrItemNumber = vbNullString Then
      sstrItemNumber = Sheet1.ListObjects(str_Table1).HeaderRowRange(1).Value2
    End If
    str_ItemNumber = sstrItemNumber
End Function
Private Function str_ItemName() As String
    Static sstrItemName As String
    If sstrItemName = vbNullString Then
      sstrItemName = Sheet1.ListObjects(str_Table1).HeaderRowRange(2).Value2
    End If
    str_ItemName = sstrItemName
End Function

Public Function ITEM_NAME(ByRef Item_ID As Variant) As String
  'Returns Item Name as a function of Item Number.
  Dim ƒ As WorksheetFunction: Set ƒ = WorksheetFunction
  With Sheet1.ListObjects(str_Table1)
    ITEM_NAME _
    = ƒ.Index _
      ( _
        .ListColumns(str_ItemName).DataBodyRange _
      , ƒ.Match(Item_ID, .ListColumns(str_ItemNumber).DataBodyRange) _
      )
  End With
End Function

обратите внимание на использование .Value2. Я всегда использовал .Value2 С тех пор, как я узнал о перетаскивании производительности и других проблемах, вызванных неявным преобразованием типа, выполненным при использовании .Value (или при использовании его в качестве свойства по умолчанию).

_{* не забудьте обновить имена заголовков столбцов в коде, когда логика/дизайн проекта будет завершен.}

EDIT: (перезагрузить)

перечитывая ваши собственные комментарии к вашему опубликованному вопросу, я отметил этот:

я мог бы принять этот подход в конечном итоге, но я все еще в процессе проектирования и перемещения столбцы вокруг много, поэтому номер индекса также может измениться

в то время как последний пример выше позволяет динамически изменять имена заголовков, перемещение/вставка столбцов изменяет индексы, требуя изменения кода.

Похоже, мы вернулись к использованию именованных диапазонов. Однако на этот раз нам нужны только статические, указывающие на столбец заголовки.

также оказывается, что для этого нового случая статические переменные являются плохо идея на стадии проектирования. Поскольку индексы столбцов кэшируются, вставка нового столбца разрывает UDF до сброса проекта.

я также включил сокращенную версию таблицы без листа ссылки Хак из цитаты в вашем опубликованном вопросе:

Option Explicit

Private Function str_Table1() As String
    str_Table1 = Sheet1.ListObjects(1).Name
End Function
Private Function str_ItemNumber() As String
    With Range(str_Table1).ListObject
      str_ItemNumber = .HeaderRowRange(.Parent.Range("A3").Column - .HeaderRowRange.Column + 1).Value2
    End With
End Function
Private Function str_ItemName() As String
    With Range(str_Table1).ListObject
      str_ItemName = .HeaderRowRange(.Parent.Range("B3").Column - .HeaderRowRange.Column + 1).Value2
    End With
End Function

Public Function ITEM_NAME(ByRef Item_ID As Variant) As String
  'Returns Item Name as a function of Item Number.
  Dim ƒ As WorksheetFunction: Set ƒ = WorksheetFunction
  With Range(str_Table1).ListObject
    ITEM_NAME _
    = ƒ.Index _
      ( _
        .ListColumns(str_ItemName).DataBodyRange _
      , ƒ.Match(Item_ID, .ListColumns(str_ItemNumber).DataBodyRange) _
      )
  End With
End Function

обратите внимание, что вы не можете использовать Item_name для одного из именованных диапазонов, так как он совпадает с UDF (случай игнорируется). Я предлагаю использовать конечное подчеркивание, например,Item_name_, для именованный диапазон.

все вышеперечисленные методы также решили бы оригинальную проблему, которая у вас была. Я жду последней информации, чтобы сделать обоснованное предположение о том, почему эта проблема возникла в первую очередь.