Tcl / Tk примеры?
Tcl / Tk это простой способ написания небольших GUIs.
может ли кто - нибудь дать хороший пример с и a текст виджет. Когда кнопка нажата, должна быть выполнена команда оболочки, а вывод передан в текст виджет.
Если у вас есть другие хорошие и чистые примеры для полезной работы, пожалуйста, добавьте их.
4 ответов
вот более полный пример использования fileevents. Это будет автоматически прокручиваться все время. Для удобства использования вы, вероятно, хотите только автоматически прокручивать, если нижняя часть текста видна (т. е.: если пользователь не переместил полосу прокрутки), но я оставлю это в качестве упражнения для читателя, чтобы этот уже длинный пример не становился больше.
package require Tk
proc main {} {
if {[lsearch -exact [font names] TkDefaultFont] == -1} {
# older versions of Tk don't define this font, so pick something
# suitable
font create TkDefaultFont -family Helvetica -size 12
}
# in 8.5 we can use {*} but this will work in earlier versions
eval font create TkBoldFont [font actual TkDefaultFont] -weight bold
buildUI
}
proc buildUI {} {
frame .toolbar
scrollbar .vsb -command [list .t yview]
text .t \
-width 80 -height 20 \
-yscrollcommand [list .vsb set] \
-highlightthickness 0
.t tag configure command -font TkBoldFont
.t tag configure error -font TkDefaultFont -foreground firebrick
.t tag configure output -font TkDefaultFont -foreground black
grid .toolbar -sticky nsew
grid .t .vsb -sticky nsew
grid rowconfigure . 1 -weight 1
grid columnconfigure . 0 -weight 1
set i 0
foreach {label command} {
date {date}
uptime {uptime}
ls {ls -l}
} {
button .b$i -text $label -command [list runCommand $command]
pack .b$i -in .toolbar -side left
incr i
}
}
proc output {type text} {
.t configure -state normal
.t insert end $text $type "\n"
.t see end
.t configure -state disabled
}
proc runCommand {cmd} {
output command $cmd
set f [open "| $cmd" r]
fconfigure $f -blocking false
fileevent $f readable [list handleFileEvent $f]
}
proc closePipe {f} {
# turn blocking on so we can catch any errors
fconfigure $f -blocking true
if {[catch {close $f} err]} {
output error $err
}
}
proc handleFileEvent {f} {
set status [catch { gets $f line } result]
if { $status != 0 } {
# unexpected error
output error $result
closePipe $f
} elseif { $result >= 0 } {
# we got some output
output normal $line
} elseif { [eof $f] } {
# End of file
closePipe $f
} elseif { [fblocked $f] } {
# Read blocked, so do nothing
}
}
main
несколько советов:
для добавления вывода в текст виджет, вместо указания строки 999999, вы можете использовать индекс конец, что относится к позиции сразу после последней новой строки. Например,
.main insert end "$x\n"
чтобы прокрутить текст при выводе команды, используйте посмотреть. Например, после добавления к .основной текст виджет
.main see end
вы также можете рассмотреть возможность захвата команда выводится асинхронно, с помощью fileevent.
Я могу дать старт...пожалуйста, предложите улучшения. Т. е. я бы хотел, чтобы он прокручивался, поскольку команда выводит
#!/usr/bin/wish
proc push_button {} {
put_text
.main see end
}
proc put_text {} {
set f [ open "| date" r]
while {[gets $f x] >= 0} {
.main insert end "$x\n"
}
catch {close $f}
}
button .but -text "Push Me" -command "push_button"
text .main -relief sunken -bd 2 -yscrollcommand ".scroll set"
scrollbar .scroll -command ".main yview"
pack .but
pack .main -side left -fill y
pack .scroll -side right -fill y