Включение удаленных подключений tcpip к уже установленной базе данных sql server express с кодом или сценарием (запрос)

Я тестировал ниже код SQL Server 2008 R2 Express и я считаю, что мы должны иметь решение для всех 6 шагов, которые вы наметили. Давайте возьмемся за них один за другим:

1-Включить TCP / IP

мы можем включить протокол TCP/IP с WMI:

set wmiComputer = GetObject( _
    "winmgmts:" _
    & "\.\root\Microsoft\SqlServer\ComputerManagement10")
set tcpProtocols = wmiComputer.ExecQuery( _
    "select * from ServerNetworkProtocol " _
    & "where InstanceName = 'SQLEXPRESS' and ProtocolName = 'Tcp'")

if tcpProtocols.Count = 1 then
    ' set tcpProtocol = tcpProtocols(0)
    ' I wish this worked, but unfortunately 
    ' there's no int-indexed Item property in this type

    ' Doing this instead
    for each tcpProtocol in tcpProtocols
        dim setEnableResult
            setEnableResult = tcpProtocol.SetEnable()
            if setEnableResult <> 0 then 
                Wscript.Echo "Failed!"
            end if
    next
end if

2-Откройте правильные порты в брандмауэре

Я считаю, что ваше решение будет работать, просто убедитесь, что вы указали правильный порт. Я предлагаю выбрать другой порт, чем 1433 и сделайте его статическим портом, который будет прослушиваться SQL Server Express. Я буду использовать 3456 в этом посте, но, Пожалуйста, выберите другой номер в реальной реализации (я чувствую, что мы увидим много приложений, использующих 3456 в ближайшее время: -)

3-Изменить свойства TCP / IP включить IP-адрес

мы можем использовать WMI снова. Так как мы используем статический порт 3456, нам просто нужно обновить два свойства в раздела ipall раздел: отключите динамические порты и установите прослушивание порт 3456:

set wmiComputer = GetObject( _
    "winmgmts:" _
    & "\.\root\Microsoft\SqlServer\ComputerManagement10")
set tcpProperties = wmiComputer.ExecQuery( _
    "select * from ServerNetworkProtocolProperty " _
    & "where InstanceName='SQLEXPRESS' and " _
    & "ProtocolName='Tcp' and IPAddressName='IPAll'")

for each tcpProperty in tcpProperties
    dim setValueResult, requestedValue

    if tcpProperty.PropertyName = "TcpPort" then
        requestedValue = "3456"
    elseif tcpProperty.PropertyName ="TcpDynamicPorts" then
        requestedValue = ""
    end if

    setValueResult = tcpProperty.SetStringValue(requestedValue)
    if setValueResult = 0 then 
        Wscript.Echo "" & tcpProperty.PropertyName & " set."
    else
        Wscript.Echo "" & tcpProperty.PropertyName & " failed!"
    end if
next

обратите внимание, что мне не нужно было включать какой-либо из отдельных адресов, чтобы заставить его работать, но если это требуется в вашем случае, вы должны иметь возможность легко расширить этот скрипт.

просто напоминание о том, что при работе с WMI, WBEMTest.exe - это ваш лучший друг!

4-включить проверку подлинности в смешанном режиме в sql server

Я хотел бы, чтобы мы могли использовать WMI снова, но, к сожалению, этот параметр не выставляется через WMI. Есть еще два варианта:

1. использовать LoginMode собственность Microsoft.SqlServer.Management.Smo.Server класс, как описано здесь.

2. используйте значение LoginMode в реестре SQL Server, как описано в этот пост. Обратите внимание, что по умолчанию экземпляр SQL Server Express называется SQLEXPRESS, поэтому для моего экземпляра SQL Server 2008 R2 Express правильный раздел реестра был HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Microsoft SQL Server\MSSQL10_50.SQLEXPRESS\MSSQLServer.

5 - Смена пользователя (sa) пароль по умолчанию

у вас есть это покрыто.

6-наконец (подключение к экземпляру)

поскольку мы используем статический порт, назначенный нашему экземпляру SQL Server Express, больше нет необходимости использовать имя экземпляра в адресе сервера.

SQLCMD -U sa -P newPassword -S 192.168.0.120,3456

пожалуйста, дайте мне знать, если это работает для вас (пальцы скрещенными!).