Вставка в Oracle и получение сгенерированного идентификатора последовательности

У меня есть несколько необработанных SQL-запросов для SQL Server, которые используют SCOPE_IDENTITY для получения сгенерированного идентификатора для конкретной вставки сразу после того, как эта вставка происходит все в одном исполнении...

INSERT into Batch(
BatchName,
BatchType,
Source,
Area
) Values (
@strBatchName,
@strType,
@strSource,
@intArea
);

SELECT SCOPE_IDENTITY() BatchID;

вопрос:

каков наилучший способ сделать это для базы данных Oracle?

можно ли это сделать на Oracle через стандартный SQL или мне нужно переключить это, чтобы использовать хранимую процедуру и поместить что-то подобное в тело сохраненного proc?

Если это должен быть сохраненный proc, то каков де-факто стандартный способ получения последнего сгенерированного порядкового номера, заботясь о том, чтобы учесть, что, вероятно, будут перекрывающиеся выполнения на нескольких потоках, поэтому этот механизм должен будет получить правильный сгенерированный ID и не обязательно абсолютный последний сгенерированный ID.

Если два выполняются одновременно, каждый должен возвращать правильный сгенерированный идентификатор из каждого соответствующего вызова. Обратите внимание, что я не использую SQL Server "@@IDENTITY " из-за этого многопоточного характера вызовов.

Я бы предпочел сохранить его как raw SQL, если это возможно, так как мне намного проще управлять на разных платформах (один файл, содержащий SQL-блок каждой платформы, разделенный тегами идентификации СУБД). Хранимые процессы-это немного больше работы для меня, но я могу пойти этим путем, если это единственный возможный способ.

25
identity-column oracle scope-identity sql stored-procedures

5 ответов

немного расширяя ответы от @Guru и @Ronnis, вы можете скрыть последовательность и сделать ее более похожей на автоматическое приращение с помощью триггера и иметь процедуру, которая делает вставку для вас и возвращает сгенерированный идентификатор в качестве параметра out.

create table batch(batchid number,
    batchname varchar2(30),
    batchtype char(1),
    source char(1),
    intarea number)
/

create sequence batch_seq start with 1
/

create trigger batch_bi
before insert on batch
for each row
begin
    select batch_seq.nextval into :new.batchid from dual;
end;
/

create procedure insert_batch(v_batchname batch.batchname%TYPE,
    v_batchtype batch.batchtype%TYPE,
    v_source batch.source%TYPE,
    v_intarea batch.intarea%TYPE,
    v_batchid out batch.batchid%TYPE)
as
begin
    insert into batch(batchname, batchtype, source, intarea)
    values(v_batchname, v_batchtype, v_source, v_intarea)
    returning batchid into v_batchid;
end;
/

затем вы можете вызвать процедуру вместо простой вставки, например, из anoymous блок:

declare
    l_batchid batch.batchid%TYPE;
begin
    insert_batch(v_batchname => 'Batch 1',
        v_batchtype => 'A',
        v_source => 'Z',
        v_intarea => 1,
        v_batchid => l_batchid);
    dbms_output.put_line('Generated id: ' || l_batchid);

    insert_batch(v_batchname => 'Batch 99',
        v_batchtype => 'B',
        v_source => 'Y',
        v_intarea => 9,
        v_batchid => l_batchid);
    dbms_output.put_line('Generated id: ' || l_batchid);
end;
/

Generated id: 1
Generated id: 2

вы можете сделать вызов без явного анонимного блока, например из SQL * Plus:

variable l_batchid number;
exec insert_batch('Batch 21', 'C', 'X', 7, :l_batchid);

... и используйте переменную bind :l_batchid чтобы впоследствии ссылаться на сгенерированное значение:

print l_batchid;
insert into some_table values(:l_batch_id, ...);
29

в Oracle нет функций автоматического увеличения для столбца. Вам нужно создать объект SEQUENCE. Вы можете использовать последовательность, как:

insert into table(batch_id, ...) values(my_sequence.nextval, ...)

...чтобы вернуть следующий номер. Чтобы узнать последнюю созданную последовательность nr (в вашем сеансе), вы должны использовать:

my_sequence.currval

этот сайт имеет несколько полных примеров использования последовательностей.

19

делать это как хранимая процедура имеет много преимуществ. Вы можете получить последовательность, вставленную в таблицу, используя синтаксис insert into table_name values returning.

как:

declare
some_seq_val  number;
lv_seq        number;
begin
some_seq_val := your_seq.nextval;
insert into your_tab (col1, col2, col3) 
values (some_seq_val, val2, val3) returning some_seq_val into lv_seq;

dbms_output.put_line('The inserted sequence is: '||to_char(lv_seq));
end;
/

или просто вернуть some_seq_val. В случае, если вы не используете последовательность и прибываете последовательность по некоторым расчетам, вы можете использовать returning into эффективно.

11

вы можете использовать приведенную ниже инструкцию, чтобы получить вставленный идентификатор переменной.

INSERT INTO  YOUR_TABLE(ID) VALUES ('10') returning ID into :Inserted_Value;

теперь вы можете получить значение, используя оператор

SELECT :Inserted_Value FROM DUAL;
8

вы можете сделать это с помощью одного оператора-предполагая, что вы вызываете его из JDBC-подобного соединителя с функциональностью параметров in/out:

insert into batch(batchid, batchname) 
values (batch_seq.nextval, 'new batch')
returning batchid into :l_batchid;

или, как скрипт PL-sql:

variable l_batchid number;

insert into batch(batchid, batchname) 
values (batch_seq.nextval, 'new batch')
returning batchid into :l_batchid;

select :l_batchid from dual;
0